Adding code and tests,.

utPLSQL · jgebal · Feb 4, 2022 · Jun 1, 2020 · Jun 2, 2020 · Jun 2, 2020
commit 8ff4f6bbf847bab652a1628aa68abc140655d7fe
diff --git a/source/core/ut_utils.pkb b/source/core/ut_utils.pkb
@@ -877,5 +877,30 @@ create or replace package body ut_utils is
         end;
   end;
 
+  function interval_to_text(a_interval dsinterval_unconstrained) return varchar2 is
+    l_day varchar2(100) := extract(day  from a_interval); 
+    l_hour varchar2(100) := extract(hour  from a_interval); 
+    l_minute varchar2(100) := extract(minute  from a_interval);
+    l_second varchar2(100) := extract(second from a_interval);     
+    l_result varchar2(32767);  
+  begin
+    l_result := case when l_day > 0 then l_day ||' day' else null end;
+    l_result := l_result || case when l_hour > 0 then ' '|| l_hour ||' hour' else null end;
+    l_result := l_result || case when l_minute> 0 then ' '||l_minute ||' minute' else null end; 
+    l_result := l_result || case when l_second > 0 then ' '||l_second ||' second' else null end;    
+    return trim(leading ' ' from l_result);
+  end;
+
+  function interval_to_text(a_interval yminterval_unconstrained) return varchar2 is
+    l_year varchar2(4) :=  extract(year from a_interval); 
+    l_month varchar2(20) := extract(month from a_interval);   
+    l_result varchar2(32767);     
+  begin
+    l_result := case when l_year > 0 then l_year ||' year' else null end;
+    l_result := l_result || case when l_month > 0 then  ' '||l_month ||' month' else null end;   
+    return trim(leading ' ' from l_result);
+  end;
+
+
 end ut_utils;
 /
diff --git a/source/core/ut_utils.pks b/source/core/ut_utils.pks
@@ -434,6 +434,13 @@ create or replace package ut_utils authid definer is
   * If null value passed returns null
   */
   function qualified_sql_name(a_name varchar2) return varchar2;
-
+
+  /*
+  * Return value of interval in plain english
+  */  
+  function interval_to_text(a_interval dsinterval_unconstrained) return varchar2;
+
+  function interval_to_text(a_interval yminterval_unconstrained) return varchar2;
+
 end ut_utils;
 /
diff --git a/source/expectations/data_values/ut_data_value_dsinterval.tpb b/source/expectations/data_values/ut_data_value_dsinterval.tpb
@@ -31,7 +31,7 @@ create or replace type body ut_data_value_dsinterval as
 
   overriding member function to_string return varchar2 is
   begin
-    return ut_utils.to_string(self.data_value);
+    return ut_utils.interval_to_text(self.data_value);
   end;
 
   overriding member function compare_implementation(a_other ut_data_value) return integer is

diff --git a/source/expectations/data_values/ut_data_value_yminterval.tpb b/source/expectations/data_values/ut_data_value_yminterval.tpb
@@ -31,7 +31,7 @@ create or replace type body ut_data_value_yminterval as
 
   overriding member function to_string return varchar2 is
   begin
-    return ut_utils.to_string(self.data_value);
+    return ut_utils.interval_to_text(self.data_value);
   end;
 
   overriding member function compare_implementation(a_other ut_data_value) return integer is

diff --git a/source/expectations/matchers/ut_be_within.tpb b/source/expectations/matchers/ut_be_within.tpb
@@ -0,0 +1,104 @@
+create or replace type body ut_be_within as
+  /*
+  utPLSQL - Version 3
+  Copyright 2016 - 2019 utPLSQL Project
+
+  Licensed under the Apache License, Version 2.0 (the "License"):
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+  */
+
+ member procedure init(self in out nocopy ut_be_within, a_dist ut_data_value, a_is_pct number , a_self_type varchar2 := null) is
+  begin
+    self.dist  := a_dist;
+    self.is_pct := nvl(a_is_pct,0);
+    self.self_type := nvl( a_self_type, $$plsql_unit );
+  end;
+
+  constructor function ut_be_within(self in out nocopy ut_be_within, a_dist number, a_is_pct number) return self as result is
+  begin
+    init(ut_data_value_number(a_dist),a_is_pct);
+    return;
+  end;
+
+  constructor function ut_be_within(self in out nocopy ut_be_within, a_dist dsinterval_unconstrained, a_is_pct number) return self as result is
+  begin
+    init(ut_data_value_dsinterval(a_dist),a_is_pct); 
+    return;
+  end;
+
+  constructor function ut_be_within(self in out nocopy ut_be_within, a_dist yminterval_unconstrained, a_is_pct number) return self as result is
+  begin
+    init(ut_data_value_yminterval(a_dist),a_is_pct);
+    return;
+  end;
+
+  member procedure of_(self in ut_be_within, a_expected number) is
+    l_result ut_be_within := self;
+  begin 
+    l_result.expected := ut_data_value_number(a_expected);
+    l_result.expectation.to_(l_result );        
+  end;
+
+  member procedure of_(self in ut_be_within, a_expected date) is
+    l_result ut_be_within := self;
+  begin 
+    l_result.expected := ut_data_value_date(a_expected);
+    l_result.expectation.to_(l_result );    
+  end;
+
+  overriding member function run_matcher(self in out nocopy ut_be_within, a_actual ut_data_value) return boolean is
+    l_result boolean;
+  begin
+    if self.expected.data_type = a_actual.data_type then
+      if self.expected is of (ut_data_value_number) and self.is_pct = 0 then
+        l_result := abs((treat(self.expected as ut_data_value_number).data_value - treat(a_actual as ut_data_value_number).data_value)) <= treat(self.dist as ut_data_value_number).data_value;
+      elsif self.expected is of (ut_data_value_number) and self.is_pct = 1 then
+        l_result := treat(self.dist as ut_data_value_number).data_value >= ((treat(self.expected as ut_data_value_number).data_value - treat(a_actual as ut_data_value_number).data_value ) * 100 ) /
+                    (treat(self.expected as ut_data_value_number).data_value) ;      
+      elsif self.expected is of (ut_data_value_date) and self.dist is of ( ut_data_value_yminterval) then      
+        l_result := treat(a_actual as ut_data_value_date).data_value between (treat(self.expected as ut_data_value_date).data_value) - treat(self.dist as ut_data_value_yminterval).data_value
+                    and (treat(self.expected as ut_data_value_date).data_value) + treat(self.dist as ut_data_value_yminterval).data_value;
+      elsif self.expected is of (ut_data_value_date) and self.dist is of ( ut_data_value_dsinterval) then      
+        l_result := treat(a_actual as ut_data_value_date).data_value between (treat(self.expected as ut_data_value_date).data_value) - treat(self.dist as ut_data_value_dsinterval).data_value
+                    and (treat(self.expected as ut_data_value_date).data_value) + treat(self.dist as ut_data_value_dsinterval).data_value;
+      end if;
+    else
+      l_result := (self as ut_matcher).run_matcher(a_actual);
+    end if;
+    return l_result;
+  end;
+
+  overriding member function failure_message(a_actual ut_data_value) return varchar2 is
+    l_distance varchar2(32767);
+  begin
+    l_distance := case 
+                    when self.dist is of (ut_data_value_number) then
+                      treat(self.dist as ut_data_value_number).to_string
+                    when self.dist is of (ut_data_value_yminterval) then
+                      treat(self.dist as ut_data_value_yminterval).to_string 
+                    when self.dist is of (ut_data_value_dsinterval) then
+                      treat(self.dist as ut_data_value_dsinterval).to_string 
+                    else
+                      null
+                    end;
+
+    return (self as ut_matcher).failure_message(a_actual) || ' '||l_distance ||' of '|| expected.to_string_report();
+  end;
+
+  overriding member function failure_message_when_negated(a_actual ut_data_value) return varchar2 is
+    l_result varchar2(32767);
+  begin
+    return (self as ut_matcher).failure_message_when_negated(a_actual) || ': '|| expected.to_string_report();
+  end;  
+
+end;
+/
diff --git a/source/expectations/matchers/ut_be_within.tps b/source/expectations/matchers/ut_be_within.tps
@@ -0,0 +1,38 @@
+create or replace type ut_be_within under ut_comparison_matcher(
+  /*
+  utPLSQL - Version 3
+  Copyright 2016 - 2019 utPLSQL Project
+
+  Licensed under the Apache License, Version 2.0 (the "License"):
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+  */
+
+
+  /**
+  * Holds information about mather options
+  */
+  dist ut_data_value,
+  is_pct number(1,0),
+
+  member procedure init(self in out nocopy ut_be_within, a_dist ut_data_value, a_is_pct number , a_self_type varchar2 := null),
+  constructor function ut_be_within(self in out nocopy ut_be_within, a_dist number, a_is_pct number) return self as result,
+  constructor function ut_be_within(self in out nocopy ut_be_within, a_dist dsinterval_unconstrained, a_is_pct number) return self as result,
+  constructor function ut_be_within(self in out nocopy ut_be_within, a_dist yminterval_unconstrained, a_is_pct number) return self as result,
+  member procedure of_(self in ut_be_within, a_expected number),
+  member procedure of_(self in ut_be_within, a_expected date),
+
+  overriding member function run_matcher(self in out nocopy ut_be_within, a_actual ut_data_value) return boolean,
+  overriding member function failure_message(a_actual ut_data_value) return varchar2,
+  overriding member function failure_message_when_negated(a_actual ut_data_value) return varchar2
+)
+not final
+/
diff --git a/source/expectations/matchers/ut_matcher.tps b/source/expectations/matchers/ut_matcher.tps
@@ -17,7 +17,7 @@ create or replace type ut_matcher under ut_matcher_base(
   */
   is_errored      integer,
   is_negated_flag number(1,0),
-  expectation     ut_expectation,
+  expectation     ut_expectation_base,
   /*
     function: run_matcher
 

diff --git a/source/expectations/ut_expectation.tpb b/source/expectations/ut_expectation.tpb
@@ -15,31 +15,6 @@ create or replace type body ut_expectation as
   See the License for the specific language governing permissions and
   limitations under the License.
   */
-  member procedure to_(self in ut_expectation, a_matcher ut_matcher_base) is
-    l_expectation_result boolean;
-    l_matcher       ut_matcher := treat(a_matcher as ut_matcher);
-    l_message       varchar2(32767);
-  begin
-    if l_matcher.is_negated() then
-      self.not_to( a_matcher );
-    else
-      l_expectation_result := l_matcher.run_matcher( self.actual_data );
-      l_expectation_result := coalesce(l_expectation_result,false);
-      l_message := coalesce( l_matcher.error_message( self.actual_data ), l_matcher.failure_message( self.actual_data ) );
-      ut_expectation_processor.add_expectation_result( ut_expectation_result( ut_utils.to_test_result( l_expectation_result ), self.description, l_message ) );
-    end if;
-  end;
-
-  member procedure not_to(self in ut_expectation, a_matcher ut_matcher_base) is
-    l_expectation_result boolean;
-    l_matcher       ut_matcher := treat(a_matcher as ut_matcher);
-    l_message       varchar2(32767);
-  begin
-    l_expectation_result := coalesce( l_matcher.run_matcher_negated( self.actual_data ), false );
-
-    l_message := coalesce( l_matcher.error_message( self.actual_data ), l_matcher.failure_message_when_negated( self.actual_data ) );
-    ut_expectation_processor.add_expectation_result( ut_expectation_result( ut_utils.to_test_result( l_expectation_result ), self.description, l_message ) );
-  end;
 
   member procedure to_be_null(self in ut_expectation) is
   begin
@@ -719,5 +694,37 @@ create or replace type body ut_expectation as
     self.not_to( ut_contain(a_expected).negated() );
   end;
 
+  member function  to_be_within(a_dist natural) return ut_be_within is
+    l_result ut_matcher;
+  begin
+    l_result := ut_be_within(a_dist,0);
+    l_result.expectation := self;
+    return treat(l_result as ut_be_within);
+  end;  
+
+  member function  to_be_within(a_dist dsinterval_unconstrained) return ut_be_within is
+    l_result ut_matcher;
+  begin
+    l_result := ut_be_within(a_dist,0);
+    l_result.expectation := self;
+    return treat(l_result as ut_be_within);
+  end;  
+
+  member function  to_be_within(a_dist yminterval_unconstrained) return ut_be_within is
+    l_result ut_matcher;
+  begin
+    l_result := ut_be_within(a_dist,0);
+    l_result.expectation := self;
+    return treat(l_result as ut_be_within);
+  end;  
+
+ member function  to_be_within_pct(a_dist natural) return ut_be_within is 
+    l_result ut_matcher;
+  begin
+    l_result := ut_be_within(a_dist,1);
+    l_result.expectation := self;
+    return treat(l_result as ut_be_within);
+  end;  
+
 end;
 /
diff --git a/source/expectations/ut_expectation.tps b/source/expectations/ut_expectation.tps
@@ -1,4 +1,4 @@
-create or replace type ut_expectation authid current_user as object(
+create or replace type ut_expectation under ut_expectation_base(
   /*
   utPLSQL - Version 3
   Copyright 2016 - 2019 utPLSQL Project
@@ -15,13 +15,7 @@ create or replace type ut_expectation authid current_user as object(
   See the License for the specific language governing permissions and
   limitations under the License.
   */
-  actual_data         ut_data_value,
-  description         varchar2(4000 char),
-
-  --base matcher executors
-  member procedure to_(self in ut_expectation, a_matcher ut_matcher_base),
-  member procedure not_to(self in ut_expectation, a_matcher ut_matcher_base),
-
+
   --shortcuts
   member procedure to_be_null(self in ut_expectation),
   member procedure to_be_not_null(self in ut_expectation),
@@ -168,8 +162,12 @@ create or replace type ut_expectation authid current_user as object(
   member procedure to_contain(self in ut_expectation, a_expected sys_refcursor),
   member procedure not_to_contain(self in ut_expectation, a_expected sys_refcursor),
   member procedure to_contain(self in ut_expectation, a_expected anydata),
-  member procedure not_to_contain(self in ut_expectation, a_expected anydata)
+  member procedure not_to_contain(self in ut_expectation, a_expected anydata),
 
+  member function  to_be_within(a_dist natural) return ut_be_within,
+  member function  to_be_within(a_dist dsinterval_unconstrained) return ut_be_within,
+  member function  to_be_within(a_dist yminterval_unconstrained) return ut_be_within,
+  member function  to_be_within_pct(a_dist natural) return ut_be_within
 )
 not final
 /
diff --git a/source/expectations/ut_expectation_base.tpb b/source/expectations/ut_expectation_base.tpb
@@ -0,0 +1,44 @@
+create or replace type body ut_expectation_base as
+  /*
+  utPLSQL - Version 3
+  Copyright 2016 - 2019 utPLSQL Project
+
+  Licensed under the Apache License, Version 2.0 (the "License"):
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+  */
+  member procedure to_(self in ut_expectation_base, a_matcher ut_matcher_base) is
+    l_expectation_result boolean;
+    l_matcher       ut_matcher := treat(a_matcher as ut_matcher);
+    l_message       varchar2(32767);
+  begin
+    if l_matcher.is_negated() then
+      self.not_to( a_matcher );
+    else
+      l_expectation_result := l_matcher.run_matcher( self.actual_data );
+      l_expectation_result := coalesce(l_expectation_result,false);
+      l_message := coalesce( l_matcher.error_message( self.actual_data ), l_matcher.failure_message( self.actual_data ) );
+      ut_expectation_processor.add_expectation_result( ut_expectation_result( ut_utils.to_test_result( l_expectation_result ), self.description, l_message ) );
+    end if;
+  end;
+
+  member procedure not_to(self in ut_expectation_base, a_matcher ut_matcher_base) is
+    l_expectation_result boolean;
+    l_matcher       ut_matcher := treat(a_matcher as ut_matcher);
+    l_message       varchar2(32767);
+  begin
+    l_expectation_result := coalesce( l_matcher.run_matcher_negated( self.actual_data ), false );
+
+    l_message := coalesce( l_matcher.error_message( self.actual_data ), l_matcher.failure_message_when_negated( self.actual_data ) );
+    ut_expectation_processor.add_expectation_result( ut_expectation_result( ut_utils.to_test_result( l_expectation_result ), self.description, l_message ) );
+  end;
+end;
+/  
diff --git a/source/expectations/ut_expectation_base.tps b/source/expectations/ut_expectation_base.tps
@@ -0,0 +1,25 @@
+create or replace type ut_expectation_base force authid current_user as object(
+  /*
+  utPLSQL - Version 3
+  Copyright 2016 - 2019 utPLSQL Project
+
+  Licensed under the Apache License, Version 2.0 (the "License"):
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+  */
+  actual_data         ut_data_value,
+  description         varchar2(4000 char),
+
+  --base matcher executors
+  member procedure to_(self in ut_expectation_base, a_matcher ut_matcher_base),
+  member procedure not_to(self in ut_expectation_base, a_matcher ut_matcher_base)
+) not final
+/