plugins {

id("java-library")

id("objectbox.publishing-conventions")

}

// Note: use release flag instead of sourceCompatibility and targetCompatibility to ensure only JDK 8 API is used.

// https://docs.gradle.org/current/userguide/building_java_projects.html#sec:java_cross_compilation

tasks.withType<JavaCompile> {

options.release.set(8)

}

val javadocJar by tasks.registering(Jar::class) {

dependsOn(tasks.javadoc)

archiveClassifier.set("javadoc")

from("build/docs/javadoc")

}

val sourcesJar by tasks.registering(Jar::class) {

from(sourceSets.main.get().allSource)

archiveClassifier.set("sources")

}

// Note: common settings applied by objectbox.publishing-conventions plugin

val publicationObjectboxJavaApi = "objectboxJavaApi"

publishing {

publications {

create<MavenPublication>(publicationObjectboxJavaApi) {

artifactId = "objectbox-java-api"

from(components["java"])

artifact(sourcesJar)

artifact(javadocJar)

pom {

name.set("ObjectBox Java Annotations")

description.set("ObjectBox is a fast NoSQL database for Objects")

packaging = "jar"

}

}

}

}

signing {

sign(publishing.publications[publicationObjectboxJavaApi])

}