-
-
Notifications
You must be signed in to change notification settings - Fork 469
Expand file tree
/
Copy pathbuild.gradle.kts
More file actions
135 lines (116 loc) · 3.7 KB
/
build.gradle.kts
File metadata and controls
135 lines (116 loc) · 3.7 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
import io.gitlab.arturbosch.detekt.Detekt
import org.jetbrains.dokka.gradle.DokkaTask
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.dsl.KotlinVersion
plugins {
alias(libs.plugins.kotlin.multiplatform)
alias(libs.plugins.kotlin.compose)
id("com.android.library")
alias(libs.plugins.kover)
alias(libs.plugins.gradle.versions)
alias(libs.plugins.detekt)
alias(libs.plugins.dokka)
alias(libs.plugins.dokka.javadoc)
`maven-publish` // necessary for publishMavenLocal task to publish correct artifacts
}
kotlin {
explicitApi()
androidTarget {
compilerOptions {
jvmTarget.set(JvmTarget.JVM_1_8)
apiVersion.set(KotlinVersion.KOTLIN_1_9)
languageVersion.set(KotlinVersion.KOTLIN_1_9)
}
publishLibraryVariants("release")
}
jvm("desktop") {
compilerOptions {
jvmTarget.set(JvmTarget.JVM_1_8)
apiVersion.set(KotlinVersion.KOTLIN_1_9)
languageVersion.set(KotlinVersion.KOTLIN_1_9)
}
}
coreLibrariesVersion = "1.8"
sourceSets.all {
// Allow all experimental APIs, since MPP projects are themselves experimental
languageSettings.apply {
optIn("kotlin.Experimental")
optIn("kotlin.ExperimentalMultiplatform")
}
}
sourceSets {
val commonMain by getting {
compilerOptions {
apiVersion.set(KotlinVersion.KOTLIN_1_9)
languageVersion.set(KotlinVersion.KOTLIN_1_9)
}
}
val androidMain by getting {
dependencies {
api(projects.sentry)
api(projects.sentryAndroidNavigation)
compileOnly(libs.androidx.compose.material3)
compileOnly(libs.androidx.navigation.compose)
implementation(libs.androidx.lifecycle.common.java8)
}
}
val androidUnitTest by getting {
dependencies {
implementation(libs.androidx.compose.ui.test.junit4)
implementation(libs.androidx.navigation.compose)
implementation(libs.androidx.test.ext.junit)
implementation(libs.androidx.test.rules)
implementation(libs.androidx.test.runner)
implementation(libs.kotlin.test.junit)
implementation(libs.mockito.inline)
implementation(libs.mockito.kotlin)
implementation(libs.roboelectric)
}
}
}
}
android {
compileSdk = libs.versions.compileSdk.get().toInt()
namespace = "io.sentry.compose"
defaultConfig {
minSdk = libs.versions.minSdk.get().toInt()
// for AGP 4.1
buildConfigField("String", "VERSION_NAME", "\"${project.version}\"")
}
sourceSets["main"].apply { manifest.srcFile("src/androidMain/AndroidManifest.xml") }
buildTypes {
getByName("debug") { consumerProguardFiles("proguard-rules.pro") }
getByName("release") { consumerProguardFiles("proguard-rules.pro") }
}
testOptions {
animationsDisabled = true
unitTests.apply {
isReturnDefaultValues = true
isIncludeAndroidResources = true
}
}
lint {
warningsAsErrors = true
checkDependencies = true
// We run a full lint analysis as build part in CI, so skip vital checks for assemble tasks.
checkReleaseBuilds = false
}
buildFeatures { buildConfig = true }
androidComponents.beforeVariants {
it.enable = !Config.Android.shouldSkipDebugVariant(it.buildType)
}
}
tasks.withType<Detekt>().configureEach {
// Target version of the generated JVM bytecode. It is used for type resolution.
jvmTarget = JavaVersion.VERSION_1_8.toString()
}
tasks.withType<DokkaTask>().configureEach {
// suppress unattached source sets for docs
dokkaSourceSets {
matching {
it.name.contains("androidandroid", ignoreCase = true) ||
it.name.contains("testfixtures", ignoreCase = true)
}
.configureEach { suppress.set(true) }
}
}