/*

Feathers UI

Copyright 2026 Bowler Hat LLC. All Rights Reserved.

This program is free software. You can redistribute and/or modify it in

accordance with the terms of the accompanying license agreement.

*/

package feathers.controls;

import feathers.core.FeathersControl;

import feathers.core.IFocusManagerAware;

import feathers.core.IFocusObject;

import feathers.core.IMeasureObject;

import feathers.core.ITextControl;

import feathers.core.IUIControl;

import feathers.core.IValidating;

import feathers.events.FeathersEvent;

import feathers.layout.HorizontalAlign;

import feathers.layout.Measurements;

import feathers.layout.RelativePosition;

import feathers.layout.VerticalAlign;

import feathers.skins.IProgrammaticSkin;

import feathers.text.TextFormat;

import feathers.utils.MeasurementsUtil;

import openfl.display.DisplayObject;

import openfl.errors.ArgumentError;

import openfl.events.Event;

import openfl.events.MouseEvent;

import openfl.text.AntiAliasType;

import openfl.text.GridFitType;

import openfl.text.TextField;

#if (openfl >= "9.2.0")

import openfl.text.StyleSheet;

#elseif flash

import flash.text.StyleSheet;

#end

/**

Displays text next to a control in a form.

@see `feathers.controls.Form`

@see [Tutorial: How to use the Form and FormItem components](https://feathersui.com/learn/haxe-openfl/form/)

@since 1.0.0

**/

@defaultXmlProperty("content")

@:styleContext

class FormItem extends FeathersControl implements ITextControl implements IFocusManagerAware {

/**

Creates a new `FormItem` object.

@since 1.0.0

**/

public function new(text:String = "", ?content:DisplayObject, required:Bool = false) {

initializeFormItemTheme();

super();

this.text = text;

this.content = content;

this.required = required;

}

private var textField:TextField;

private var _previousText:String = null;

private var _previousHTMLText:String = null;

private var _previousTextFormat:TextFormat = null;

private var _previousSimpleTextFormat:openfl.text.TextFormat = null;

private var _updatedTextStyles = false;

private var _textMeasuredWidth:Float;

private var _textMeasuredHeight:Float;

private var _wrappedOnMeasure:Bool = false;

private var _text:String;

/**

The text displayed by the form item.

The following example sets the form item's text:

```haxe

formItem.text = "Address";

```

@default ""

@see `FormItem.textFormat`

@since 1.0.0

**/

@:inspectable

public var text(get, set):String;

private function get_text():String {

return this._text;

}

private function set_text(value:String):String {

if (value == null) {

// null gets converted to an empty string

if (this._text.length == 0) {

// already an empty string

return this._text;

}

value = "";

}

if (this._text == value) {

return this._text;

}

this._text = value;

this.setInvalid(DATA);

if (this._customTextColumnWidth != null && (this.textPosition == LEFT || this.textPosition == RIGHT)) {

// ensure that form updates its layout because this change could

// affect other form items too

FeathersEvent.dispatch(this, Event.RESIZE);

}

return this._text;

}

private var _htmlText:String = null;

/**

Text displayed by the label that is parsed as a simple form of HTML.

The following example sets the label's HTML text:

```haxe

label.htmlText = "<b>Hello</b> <i>World</i>";

```

@default null

@see `Label.text`

@see [`openfl.text.TextField.htmlText`](https://api.openfl.org/openfl/text/TextField.html#htmlText)

@since 1.0.0

**/

public var htmlText(get, set):String;

private function get_htmlText():String {

return this._htmlText;

}

private function set_htmlText(value:String):String {

if (this._htmlText == value) {

return this._htmlText;

}

this._htmlText = value;

this.setInvalid(DATA);

return this._htmlText;

}

/**

@see `feathers.core.ITextControl.baseline`

**/

public var baseline(get, never):Float;

private function get_baseline():Float {

if (this.textField == null) {

return 0.0;

}

var textFieldBaseline = 0.0;

// usually, hasText doesn't check the length, but TextField height may

// not be accurate with an empty string

var hasText = this._text != null && this._text.length > 0;

var hasHTMLText = this._htmlText != null && this._htmlText.length > 0;

if (hasText || hasHTMLText) {

textFieldBaseline = this.textField.y + this.textField.getLineMetrics(0).ascent;

} else {

this.textField.text = "\u200b";

textFieldBaseline = this.textField.y + this.textField.getLineMetrics(0).ascent;

this.textField.text = "";

}

var contentBaseline = 0.0;

if ((this._currentContent is ITextControl)) {

contentBaseline = this._currentContent.y + (cast this._currentContent : ITextControl).baseline;

}

return Math.max(textFieldBaseline, contentBaseline);

}

private var _contentMeasurements:Measurements = null;

private var _currentContent:DisplayObject = null;

private var _ignoreContentResize:Bool = false;

private var _content:DisplayObject;

/**

The content displayed by the form item.

The following example sets the form item's content:

```haxe

var nameInput = new TextInput();

nameInput.prompt = "First and last name";

formItem.content = nameInput;

```

@see `FormItem.text`

@since 1.0.0

**/

public var content(get, set):DisplayObject;

private function get_content():DisplayObject {

return this._content;

}

private function set_content(value:DisplayObject):DisplayObject {

if (this._content == value) {

return this._content;

}

if (this._content != null) {

this._content.removeEventListener(Event.RESIZE, formItem_content_resizeHandler);

}

this._content = value;

if (this._content != null) {

this._content.addEventListener(Event.RESIZE, formItem_content_resizeHandler, false, 0, true);

}

this.setInvalid(DATA);

return this._content;

}

private var _selectable:Bool = false;

/**

Indicates if the form item's text may be selected or not.

In the following example, the form item's text is selectable:

```haxe

formItem.selectable = true;

```

@since 1.0.0

**/

public var selectable(get, set):Bool;

private function get_selectable():Bool {

return this._selectable;

}

private function set_selectable(value:Bool):Bool {

if (this._selectable == value) {

return this._selectable;

}

this._selectable = value;

this.setInvalid(SELECTION);

return this._selectable;

}

/**

The start index of the selection.

If `selectable` is `false`, returns `-1`.

@since 1.0.0

**/

public var selectionBeginIndex(get, never):Int;

private function get_selectionBeginIndex():Int {

if (!this._selectable) {

return -1;

}

if (this.textField == null) {

return 0;

}

return this.textField.selectionBeginIndex;

}

/**

The end index of the selection.

If `selectable` is `false`, returns `-1`.

@since 1.0.0

**/

public var selectionEndIndex(get, never):Int;

private function get_selectionEndIndex():Int {

if (!this._selectable) {

return -1;

}

if (this.textField == null) {

return 0;

}

return this.textField.selectionEndIndex;

}

private var _required:Bool = false;

/**

Indicates if the form item is required. This is purely a visual

indicator, and it will not prevent the form from being submitted.

In the following example, the form item is required:

```haxe

formItem.required = true;

```

@see `FormItem.requiredSkin`

@since 1.0.0

**/

public var required(get, set):Bool;

private function get_required():Bool {

return this._required;

}

private function set_required(value:Bool):Bool {

if (this._required == value) {

return this._required;

}

this._required = value;

this.setInvalid(SELECTION);

if (this._customTextColumnWidth != null && (this.textPosition == LEFT || this.textPosition == RIGHT)) {

// ensure that form updates its layout because this change could

// affect other form items too

FeathersEvent.dispatch(this, Event.RESIZE);

}

return this._required;

}

/**

Set to false to prevent `Keyboard.ENTER` from submitting the `Form` that

contains this item.

In the following example, the form item does not submit when pressing

the enter key:

```haxe

formItem.submitOnEnterEnabled = false;

```

@since 1.0.0

**/

public var submitOnEnterEnabled:Bool = true;

private var _currentRequiredSkin:DisplayObject = null;

private var _requiredSkinMeasurements:Measurements = null;

/**

The symbol displayed if the `required` property is `true`.

In the following example, the form item's required skin is set to a bitmap:

```haxe

formItem.requiredSkin = new Bitmap(bitmapData);

```

@see `FormItem.required`

@since 1.0.0

**/

@:style

public var requiredSkin:DisplayObject = null;

/**

The font styles used to render the form item's text.

In the following example, the form item's text formatting is customized:

```haxe

formItem.textFormat = new TextFormat("Helvetica", 20, 0xcc0000);

```

@see `FormItem.text`

@see `FormItem.disabledTextFormat`

@see `FormItem.embedFonts`

@since 1.0.0

**/

@:style

public var textFormat:AbstractTextFormat = null;

#if (openfl >= "9.2.0" || flash)

/**

A custom stylesheet to use with `htmlText`.

If the `styleSheet` style is not `null`, the `textFormat` style will

be ignored.

@see `FormItem.htmlText`

@since 1.0.0

**/

@:style

public var styleSheet:StyleSheet = null;

#end

/**

The font styles used to render the form item's text when the form item

is disabled.

In the following example, the form item's disabled text formatting is

customized:

```haxe

formItem.enabled = false;

formItem.disabledTextFormat = new TextFormat("Helvetica", 20, 0xee0000);

```

@see `FormItem.textFormat`

@since 1.0.0

**/

@:style

public var disabledTextFormat:AbstractTextFormat = null;

/**

Determines if an embedded font is used or not.

In the following example, the form item uses embedded fonts:

```haxe

formItem.embedFonts = true;

```

@see `FormItem.textFormat`

@since 1.0.0

**/

@:style

public var embedFonts:Bool = false;

/**

Configures the `alpha` value of the form item's text.

In the following example, the form item's text alpha is customized:

```haxe

formItem.textAlpha = 0.5;

```

@see `FormItem.textFormat`

@see `FormItem.disabledTextAlpha`

@since 1.4.0

**/

@:style

@:inspectable(minValue = "0.0", maxValue = "1.0", verbose = "1")

public var textAlpha:Float = 1.0;

/**

When `disabledTextAlpha` is not `null`, sets the `alpha` property of the

text to this value when the the `enabled` property is set to `false`.

In the following example, the form item's disabled text alpha is customized:

```haxe

formItem.disabledTextAlpha = 0.5;

```

@see `FormItem.textAlpha`

@since 1.4.0

**/

@:style

@:inspectable(minValue = "0.0", maxValue = "1.0", verbose = "1")

public var disabledTextAlpha:Null<Float> = null;

/**

Determines the type of anti-aliasing used for embedded fonts.

In the following example, the form item uses advanced anti-aliasing:

```haxe

formItem.embedFonts = true;

formItem.antiAliasType = ADVANCED;

```

@see `FormItem.embedFonts`

@see `FormItem.gridFitType`

@since 1.4.0

**/

@:style

public var antiAliasType:AntiAliasType = NORMAL;

/**

Determines the type of anti-aliasing used for embedded fonts.

In the following example, the form item uses sub-pixel grid fitting:

```haxe

formItem.embedFonts = true;

formItem.antiAliasType = ADVANCED;

formItem.gridFitType = SUBPIXEL;

```

@see `FormItem.antiAliasType`

@see `FormItem.embedFonts`

@since 1.4.0

**/

@:style

public var gridFitType:GridFitType = PIXEL;

/**

The minimum space, in pixels, between the form item's top edge and the

form item's content.

In the following example, the form item's top padding is set to 20

pixels:

```haxe

formItem.paddingTop = 20.0;

```

@default 0.0

@since 1.0.0

**/

@:style

public var paddingTop:Float = 0.0;

/**

The minimum space, in pixels, between the form item's right edge and the

form item's content.

In the following example, the form item's right padding is set to 20

pixels:

```haxe

formItem.paddingRight = 20.0;

```

@default 0.0

@since 1.0.0

**/

@:style

public var paddingRight:Float = 0.0;

/**

The minimum space, in pixels, between the form item's bottom edge and

the form item's content.

In the following example, the form item's bottom padding is set to 20

pixels:

```haxe

formItem.paddingBottom = 20.0;

```

@default 0.0

@since 1.0.0

**/

@:style

public var paddingBottom:Float = 0.0;

/**

The minimum space, in pixels, between the form item's left edge and the

form item's content.

In the following example, the form item's left padding is set to 20

pixels:

```haxe

formItem.paddingLeft = 20.0;

```

@default 0.0

@since 1.0.0

**/

@:style

public var paddingLeft:Float = 0.0;

/**

The space, measured in pixels, between the form item's text and its

content. Applies to either horizontal or vertical spacing, depending on

the value of `textPosition`.

The following example creates a gap of 20 pixels between the text and

the content:

```haxe

formItem.text = "Name";

formItem.content = new TextInput();

formItem.gap = 20.0;

```

@since 1.0.0

**/

@:style

public var gap:Float = 0.0;

/**

How the `content` is positioned horizontally (along the x-axis) within

the available space next to the form item's text.

The following example aligns the form item's content to the right:

```haxe

formItem.verticalAlign = RIGHT;

```

@see `feathers.layout.HorizontalAlign.LEFT`

@see `feathers.layout.HorizontalAlign.CENTER`

@see `feathers.layout.HorizontalAlign.RIGHT`

@see `feathers.layout.HorizontalAlign.JUSTIFY`

@since 1.0.0

**/

@:style

public var horizontalAlign:HorizontalAlign = LEFT;

/**

How the `content` is positioned vertically (along the y-axis) within the

available space next to the form item's text.

The following example aligns the form item's content to the bottom:

```haxe

formItem.verticalAlign = BOTTOM;

```

@see `feathers.layout.VerticalAlign.TOP`

@see `feathers.layout.VerticalAlign.MIDDLE`

@see `feathers.layout.VerticalAlign.BOTTOM`

@see `feathers.layout.VerticalAlign.JUSTIFY`

@since 1.0.0

**/

@:style

public var verticalAlign:VerticalAlign = MIDDLE;

/**

Determines if the text is displayed on a single line, or if it wraps.

In the following example, the form item's text wraps:

```haxe

formItem.wordWrap = true;

```

@default false

@since 1.0.0

**/

@:style

public var wordWrap:Bool = false;

private var _customTextColumnWidth:Null<Float> = null;

private var customTextColumnWidth(get, set):Null<Float>;

private function get_customTextColumnWidth():Null<Float> {

return this._customTextColumnWidth;

}

private function set_customTextColumnWidth(value:Null<Float>):Null<Float> {

if (this._customTextColumnWidth == value) {

return this._customTextColumnWidth;

}

this._customTextColumnWidth = value;

this.setInvalid(SIZE);

return this._customTextColumnWidth;

}

private var _currentBackgroundSkin:DisplayObject = null;

private var _backgroundSkinMeasurements:Measurements = null;

/**

The default background skin to display behind the form item's content.

The following example passes a bitmap for the form item to use as a

background skin:

```haxe

formItem.backgroundSkin = new Bitmap(bitmapData);

```

@default null

@see `FormItem.disabledBackgroundSkin`

@since 1.0.0

**/

@:style

public var backgroundSkin:DisplayObject = null;

/**

A background skin to display behind the form item's content when the

form item is disabled.

The following example gives the form item a disabled background skin:

```haxe

formItem.disabledBackgroundSkin = new Bitmap(bitmapData);

formItem.enabled = false;

```

@default null

@see `FormItem.backgroundSkin`

@since 1.0.0

**/

@:style

public var disabledBackgroundSkin:DisplayObject = null;

/**

The location of the form item's text, relative to its content.

The following example positions the text to the left of the text:

```haxe

formItem.text = "Click Me";

formItem.content = new TextInput();

formItem.textPosition = LEFT;

```

@see `FormItem.text`

@since 1.0.0

**/

@:style

public var textPosition:RelativePosition = TOP;

override public function dispose():Void {

if (this._previousTextFormat != null) {

this._previousTextFormat.removeEventListener(Event.CHANGE, formItem_textFormat_changeHandler);

this._previousTextFormat = null;

}

super.dispose();

}

/**

Returns the measured width of the form item's text. Used by `Form` to

position and size all form items correctly.

@since 1.0.0

**/

public function getTextMeasuredWidth():Float {

var result = this._textMeasuredWidth;

if (this._currentRequiredSkin != null) {

result += this.gap + this._currentRequiredSkin.width;

}

return result;

}

/**

Returns the maximum allowed width of the form item's text. Used by

`Form` to position and size all form items correctly.

@since 1.0.0

**/

public function getTextMeasuredMaxWidth():Float {

if (this._explicitWidth != null) {

var textMeasuredWidth = this.getTextMeasuredWidth();

var maxWidth = this._explicitWidth;

if (this._currentContent != null) {

if ((this._currentContent is IMeasureObject)) {

maxWidth -= (cast this._currentContent : IMeasureObject).minWidth;

} else {

maxWidth -= this._currentContent.width;

}

maxWidth -= this.gap;

}

if (maxWidth < 0.0) {

maxWidth = 0.0;

}

if (textMeasuredWidth > maxWidth) {

return maxWidth;

}

}

return 1.0 / 0.0; // Math.POSITIVE_INFINITY bug workaround for swf

}

/**

Sets all four padding properties to the same value.

@see `FormItem.paddingTop`

@see `FormItem.paddingRight`

@see `FormItem.paddingBottom`

@see `FormItem.paddingLeft`

@since 1.0.0

**/

public function setPadding(value:Float):Void {

this.paddingTop = value;

this.paddingRight = value;

this.paddingBottom = value;

this.paddingLeft = value;

}

private function initializeFormItemTheme():Void {

#if !feathersui_disable_default_theme

feathers.themes.steel.components.SteelFormItemStyles.initialize();

#end

}

override private function initialize():Void {

super.initialize();

if (this.textField == null) {

this.textField = new TextField();

this.textField.multiline = true;

this.addChild(this.textField);

}

this.textField.addEventListener(MouseEvent.CLICK, formItem_textField_clickHandler);

}

override private function update():Void {

var dataInvalid = this.isInvalid(DATA);

var selectionInvalid = this.isInvalid(SELECTION);

var sizeInvalid = this.isInvalid(SIZE);

var stateInvalid = this.isInvalid(STATE);

var stylesInvalid = this.isInvalid(STYLES);

this._updatedTextStyles = false;

if (stylesInvalid || stateInvalid) {

this.refreshBackgroundSkin();

}

if (stylesInvalid || selectionInvalid) {

this.refreshRequiredSkin();

}

if (stylesInvalid || stateInvalid) {

this.refreshTextStyles();

}

if (dataInvalid || stylesInvalid || stateInvalid || sizeInvalid) {

this.refreshText(sizeInvalid);

}

if (dataInvalid || stylesInvalid || selectionInvalid) {

this.refreshSelection();

}

if (dataInvalid) {

this.refreshContent();

}

if (dataInvalid || stateInvalid) {

this.refreshEnabled();

}

sizeInvalid = this.measure() || sizeInvalid;

this.layoutContent();

}

private function measure():Bool {

var needsWidth = this.explicitWidth == null;

var needsHeight = this.explicitHeight == null;

var needsMinWidth = this.explicitMinWidth == null;

var needsMinHeight = this.explicitMinHeight == null;

var needsMaxWidth = this.explicitMaxWidth == null;

var needsMaxHeight = this.explicitMaxHeight == null;

if (!needsWidth && !needsHeight && !needsMinWidth && !needsMinHeight && !needsMaxWidth && !needsMaxHeight) {

return false;

}

if (this._currentBackgroundSkin != null) {

MeasurementsUtil.resetFluidlyWithParent(this._backgroundSkinMeasurements, this._currentBackgroundSkin, this);

}

var measureSkin:IMeasureObject = null;

if ((this._currentBackgroundSkin is IMeasureObject)) {

measureSkin = cast this._currentBackgroundSkin;

}

if ((this._currentBackgroundSkin is IValidating)) {

(cast this._currentBackgroundSkin : IValidating).validateNow();

}

if ((this._currentRequiredSkin is IValidating)) {

(cast this._currentRequiredSkin : IValidating).validateNow();

}

var measureContent:IMeasureObject = null;

if ((this._currentContent is IMeasureObject)) {

measureContent = cast this._currentContent;

}

var measureRequiredSkin:IMeasureObject = null;

if ((this._currentRequiredSkin is IMeasureObject)) {

measureRequiredSkin = cast this._currentRequiredSkin;

}

if (this._currentContent != null) {

var textWidthOffset = 0.0;

var textHeightOffset = 0.0;

if (this.textPosition == TOP || this.textPosition == BOTTOM) {

textHeightOffset = this._textMeasuredHeight + this.gap;

} else {

if (this._customTextColumnWidth != null) {

textWidthOffset = this._customTextColumnWidth + this.gap;

} else {

textWidthOffset = this._textMeasuredWidth + this.gap;

if (this._currentRequiredSkin != null) {

textWidthOffset += this._currentRequiredSkin.width + this.gap;

}

}

}

var oldIgnoreContentResize = this._ignoreContentResize;

this._ignoreContentResize = true;

if (this.horizontalAlign == JUSTIFY || this.verticalAlign == JUSTIFY) {

var justifyWidth:Null<Float> = null;

var justifyHeight:Null<Float> = null;

var justifyMinWidth:Null<Float> = null;

var justifyMinHeight:Null<Float> = null;

var justifyMaxWidth:Null<Float> = null;

var justifyMaxHeight:Null<Float> = null;

if (this.horizontalAlign == JUSTIFY) {

justifyWidth = this.explicitWidth != null ? this.explicitWidth - textWidthOffset - this.paddingLeft - this.paddingRight : null;

justifyMinWidth = this.explicitMinWidth != null ? this.explicitMinWidth - textWidthOffset - this.paddingLeft - this.paddingRight : null;

justifyMaxWidth = this.explicitMaxWidth != null ? this.explicitMaxWidth - textWidthOffset - this.paddingLeft - this.paddingRight : null;

}

if (this.verticalAlign == JUSTIFY) {

justifyHeight = this.explicitHeight != null ? this.explicitHeight - textHeightOffset - this.paddingTop - this.paddingBottom : null;

justifyMinHeight = this.explicitMinHeight != null ? this.explicitMinHeight - textHeightOffset - this.paddingLeft - this.paddingRight : null;

justifyMaxHeight = this.explicitMaxHeight != null ? this.explicitMaxHeight - textHeightOffset - this.paddingLeft - this.paddingRight : null;

}

MeasurementsUtil.resetFluidlyWithParentValues(this._contentMeasurements, this._currentContent, justifyWidth, justifyHeight, justifyMinWidth,

justifyMinHeight, justifyMaxWidth, justifyMaxHeight);

} else {

this._contentMeasurements.restore(this._currentContent);

}

if ((this._currentContent is IValidating)) {

(cast this._currentContent : IValidating).validateNow();

}

this._ignoreContentResize = oldIgnoreContentResize;

}

var newWidth = this.explicitWidth;

if (needsWidth) {

newWidth = this._textMeasuredWidth;

if (this._customTextColumnWidth != null && (this.textPosition == LEFT || this.textPosition == RIGHT)) {

newWidth = this._customTextColumnWidth;

} else if (measureRequiredSkin != null) {

newWidth += this.gap + measureRequiredSkin.width;

} else if (this._requiredSkinMeasurements != null && this._requiredSkinMeasurements.width != null) {

newWidth += this.gap + this._requiredSkinMeasurements.width;

}

newWidth += this.paddingLeft + this.paddingRight;

if (this._currentContent != null) {

if (this.textPosition == LEFT || this.textPosition == RIGHT) {

newWidth += this.gap + this._currentContent.width;

} else {

newWidth = Math.max(newWidth, this._currentContent.width + this.paddingLeft + this.paddingRight);

}

}

if (this._currentBackgroundSkin != null) {

newWidth = Math.max(this._currentBackgroundSkin.width, newWidth);

}

}

var newHeight = this.explicitHeight;

if (needsHeight) {

newHeight = this._textMeasuredHeight;

if (measureRequiredSkin != null) {

newHeight = Math.max(newHeight, measureRequiredSkin.height);

} else if (this._requiredSkinMeasurements != null && this._requiredSkinMeasurements.height != null) {

newHeight = Math.max(newHeight, this._requiredSkinMeasurements.height);

}

if (this._currentContent != null) {

if (this.textPosition == LEFT || this.textPosition == RIGHT) {

newHeight = Math.max(newHeight, this._currentContent.height);

} else // TOP or BOTTOM

{

newHeight += this.gap + this._currentContent.height;

}

}

newHeight += this.paddingTop + this.paddingBottom;

if (this._currentBackgroundSkin != null) {

newHeight = Math.max(this._currentBackgroundSkin.height, newHeight);

}

}

var newMinWidth = this.explicitMinWidth;

if (needsMinWidth) {

newMinWidth = this._textMeasuredWidth;

if (this._customTextColumnWidth != null && (this.textPosition == LEFT || this.textPosition == RIGHT)) {

newMinWidth = this._customTextColumnWidth;

} else if (measureRequiredSkin != null) {

newMinWidth += this.gap + measureRequiredSkin.width;

} else if (this._requiredSkinMeasurements != null && this._requiredSkinMeasurements.width != null) {

newMinWidth += this.gap + this._requiredSkinMeasurements.width;

}

newMinWidth += this.paddingLeft + this.paddingRight;

if (this._currentContent != null) {

if (this.textPosition == LEFT || this.textPosition == RIGHT) {

if (measureContent != null) {

newMinWidth += measureContent.minWidth;

} else {

newMinWidth += this._currentContent.width;

}

newMinWidth += this.gap;

} else // TOP or BOTTOM

{

if (measureContent != null) {

newMinWidth = Math.max(newMinWidth, measureContent.minWidth + this.paddingLeft + this.paddingRight);

} else {

newMinWidth = Math.max(newMinWidth, this._currentContent.width + this.paddingLeft + this.paddingRight);

}

}