;;; gnuplot.el --- Major-mode and interactive frontend for gnuplot -*- lexical-binding: t -*-

;; Copyright (C) 1998, 2011 Phil Type and Bruce Ravel, 1999-2012 Bruce Ravel

;; Author: Jon Oddie, Bruce Ravel, Phil Type

;; Maintainer: Maxime Tréca <maxime@gmail.com>, Daniel Mendler <mail@daniel-mendler.de>

;; Created: 1998

;; Version: 0.10

;; Keywords: data gnuplot plotting

;; URL: https://github.com/emacs-gnuplot/gnuplot

;; Package-Requires: ((emacs "28.1") (compat "30"))

;; This file is not part of GNU Emacs.

;; This program is free software: you can redistribute it and/or modify

;; it under the terms of the GNU General Public License as published by

;; the Free Software Foundation, either version 3 of the License, or

;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,

;; but WITHOUT ANY WARRANTY; without even the implied warranty of

;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License

;; along with this program. If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This is a major mode for composing gnuplot scripts and displaying

;; their results using gnuplot. It supports features of recent Gnuplot

;; versions (5.0 and up), but should also work fine with older

;; versions.

;;

;; Gnuplot-mode includes context-sensitive support for keyword

;; completion and, optionally, eldoc-mode help text. See the

;; commentary in gnuplot-context.el for more information. If you

;; don't find it useful, it can be turned off by customizing

;; `gnuplot-context-sensitive-mode'.

;;; Acknowledgements:

;; David Batty numerous corrections

;; Laurent Bonnaud suggestions regarding font-lock rules

;; Markus Dickebohm suggested `gnuplot-send-line-and-forward'

;; Stephen Eglan suggested the use of info-look and various fixes

;; Robert Fenk suggested respecting continuation lines

;; Michael Karbach suggested trimming the gnuplot process buffer

;; Alex Chan Libchen suggested font-lock for plotting words

;; Kuang-Yu Liu pointed out buggy dependence on font-lock

;; Hrvoje Niksic help with defcustom arguments for insertions

;; Andreas Rechtsteiner pointed out problem with C-c C-v

;; Michael Sanders help with the info-look interface

;; Jinwei Shen suggested functionality in comint buffer

;; Michael M. Tung prompted me to add pm3d support

;; Holger Wenzel suggested using `gnuplot-keywords-when'

;; Wolfgang Zocher pointed out problem with gnuplot-mode + speedbar

;; Jon Oddie indentation, inline images, context mode

;; Lars Hecking gnuplot distribution and installation materials

;; Maxime F. Treca package update, XEmacs deprecation

;; Daniel Mendler package update, support for recent Emacs

;;; Code:

(require 'compat)

(require 'cl-lib)

(require 'comint)

(require 'info)

(require 'info-look)

(defgroup gnuplot nil

"Gnuplot-mode for Emacs."

:prefix "gnuplot-"

:group 'processes

:group 'applications

:link '(emacs-library-link :tag "Lisp File" "gnuplot.el")

:link '(url-link :tag "Homepage" "https://github.com/emacs-gnuplot/gnuplot/")

:link '(info-link :tag "Info Manual" "(gnuplot)")

:link '(emacs-commentary-link :tag "Commentary" "gnuplot.el"))

(defcustom gnuplot-program "gnuplot"

"The name of the gnuplot executable."

:type 'string)

(defcustom gnuplot-program-args nil

"Whitespace-separated flags to pass to the gnuplot executable."

:type 'string)

(defcustom gnuplot-process-name "gnuplot"

"Name given to the gnuplot buffer and process."

:type 'string)

(defcustom gnuplot-gnuplot-buffer "plot.gp"

"The name of the gnuplot scratch buffer opened by `gnuplot-make-buffer'."

:type 'string)

(defcustom gnuplot-display-process 'window

"This controls how the gnuplot process buffer is displayed.

The values are

\\='frame display gnuplot process in a separate frame

\\='window display gnuplot process in this frame but in another window

nil `gnuplot-process' is in the current frame but not displayed"

:type '(radio (const :tag "Separate frame" frame)

(const :tag "Separate window" window)

(const :tag "Not displayed" nil)))

(defcustom gnuplot-info-display 'window

"Determines how `gnuplot-info-lookup-symbol' displays the info file.

The values are

\\='frame display info file in a separate frame

\\='window display info file in another window

nil display info file in the current window"

:type '(radio (const :tag "Separate frame" frame)

(const :tag "Separate window" window)

(const :tag "This window" nil)))

(defcustom gnuplot-echo-command-line-flag

(not (string-match "msvc" (emacs-version)))

"Non-nil means the gnuplot subprocess echoes any input.

This sets the fall-back value of `comint-process-echoes'.

If `gnuplot-mode' cannot figure out what version number of gnuplot

this is, then the value of this variable will be used for

`comint-process-echos'. It seems that gnuplot 3.5 wants this to be

nil and 3.7 wants it to be t. If lines that you send to gnuplot from

the `gnuplot-mode' buffer are not appearing at the gnuplot prompt in

the process buffer, try toggling it. Also see the document string for

`comint-process-echos'. If you change this, kill the gnuplot process

and start it again."

:type 'boolean)

(defcustom gnuplot-delay 0.02

"Amount of time to delay before sending a new line to gnuplot.

This is needed so that the the line is not written in the gnuplot

buffer in advance of its prompt. Increase this number if the

prompts and lines are displayed out of order."

:type 'number)

(defcustom gnuplot-buffer-max-size 1000

"The maximum size in lines of the gnuplot process buffer.

Each time text is written in the gnuplot process buffer, lines are

trimmed from the beginning of the buffer so that the buffer is this

many lines long. The lines are deleted after the most recent lines

were interpretted by gnuplot. Setting to 0 turns off this feature."

:type 'integer)

(defcustom gnuplot-quote-character "\'"

"Quotation character used for inserting quoted strings.

Gnuplot can use single or double quotes. If you prefer to have the

filename insertion function never insert quotes for you, set this

to the empty string."

:type '(radio (const :tag "double quote" "\"")

(const :tag "single quote" "\'")

(const :tag "none" "" )))

(defcustom gnuplot-basic-offset 4

"Number of columns to indent lines inside a do- or if-else-block.

This applies only to new-style do- and if-statements using

braces. Commands continued over a linebreak using a backslash

are always indented to line up with the second word on the line

beginning the continued command."

:type 'integer)

(defvar gnuplot-context-sensitive-mode nil)

(autoload 'gnuplot-context-sensitive-mode "gnuplot-context")

(autoload 'gnuplot-gui-set-options-and-insert "gnuplot-gui" nil '(gnuplot-mode))

(autoload 'gnuplot-gui-swap-simple-complete "gnuplot-gui" nil '(gnuplot-mode))

(autoload 'gnuplot-gui-toggle-popup "gnuplot-gui" nil '(gnuplot-mode))

(defcustom gnuplot-use-context-sensitive-completion t

"Non-nil if `gnuplot-context-sensitive-mode' should be enabled by default.

In context-sensitive mode, `gnuplot-mode' parses the current

command line to provide smarter completion and documentation

suggestions."

:type 'boolean

:set (lambda (sym value)

(set sym value)

(cond

(value

(add-hook 'gnuplot-mode-hook #'gnuplot-context-sensitive-mode nil nil)

(add-hook 'gnuplot-comint-mode-hook #'gnuplot-context-sensitive-mode nil nil))

(t

(remove-hook 'gnuplot-mode-hook #'gnuplot-context-sensitive-mode)

(remove-hook 'gnuplot-comint-mode-hook #'gnuplot-context-sensitive-mode)))

(dolist (buffer (buffer-list))

(with-current-buffer buffer

(when (derived-mode-p 'gnuplot-mode 'gnuplot-comint-mode)

(gnuplot-context-sensitive-mode (if value 1 0))))))

:link '(emacs-commentary-link "gnuplot-context"))

(defun gnuplot--set-display-mode (variable value &rest _args)

"Customize :set function for `gnuplot-inline-image-mode'.

Set VARIABLE to VALUE. ARGS is optional args."

(if (and (eq variable 'gnuplot-inline-image-mode)

value

(not (display-images-p)))

(progn

(message "Displaying images is not supported.")

(set variable nil))

(set variable value))

(gnuplot--setup-comint-for-image-mode))

(defcustom gnuplot-inline-image-mode (and (display-graphic-p)

(image-type-available-p 'png)

'inline)

"Whether to display Gnuplot output in Emacs.

Possible values are nil, `inline' and `dedicated'.

When this is nil, Gnuplot output is handled outside of Emacs in

the normal way. Otherwise, Emacs attempts to capture Gnuplot's

output and display it in a buffer. Output is inserted inline in

the Gnuplot interaction buffer it this is `inline', in a

separate dedicated buffer if it is `dedicated'.

Use Customize to set this variable, or the commands

`gnuplot-external-display-mode', `gnuplot-inline-display-mode',

and `gnuplot-dedicated-display-mode'."

:type '(radio

(const :tag "No" nil)

(const :tag "In Comint buffer" inline)

(const :tag "In dedicated buffer" dedicated))

:initialize #'custom-initialize-default

:set #'gnuplot--set-display-mode)

(defcustom gnuplot-image-format "png"

"Image format to use for displaying images within Emacs.

This will be sent directly to Gnuplot as a command of the form

\"set terminal <FORMAT>\". Common values are \"png\" and

\"svg\".

This only has an effect when `gnuplot-inline-image-mode' is

non-nil."

:type 'string

:initialize #'custom-initialize-default

:set #'gnuplot--set-display-mode)

(defcustom gnuplot-image-buffer "*gnuplot image*"

"Buffer name for dedicated gnuplot image output."

:type 'string)

(defcustom gnuplot-hidden-output-buffer " *gnuplot hidden*"

"Buffer name for hidden gnuplot output.

Send commands to GNUPLOT silently & without generating an extra prompt."

:type 'string)



;;; customizable hooks

(defgroup gnuplot-hooks nil

"Hook variables used by `gnuplot-mode'."

:prefix "gnuplot-"

:group 'gnuplot)

(defcustom gnuplot-mode-hook nil

"Hook run when `gnuplot-mode' is entered."

:type 'hook)

(defcustom gnuplot-after-plot-hook (list #'gnuplot-trim-comint-buffer)

"Hook run after gnuplot plots something.

This is the last thing done by the functions for plotting a line, a

region, a buffer, or a file."

:type 'hook)

(defcustom gnuplot-comint-mode-hook nil

"Hook run after setting up the gnuplot buffer in `gnuplot-comint-mode'."

:type 'hook)



;;; --- insertions variables and menus

(defgroup gnuplot-insertions nil

"Insert commands into gnuplot-scripts from a pull-down menu."

:prefix "gnuplot-insertions-"

:group 'gnuplot)

(defvar gnuplot--insertions-menu nil

"Menu for insertions in `gnuplot-mode'.

The insertions menu is composed of several sub-menus. The variables

describing the sub-menus are:

`gnuplot-insertions-adornments'

`gnuplot-insertions-plot-options'

`gnuplot-insertions-terminal'

`gnuplot-insertions-x-axis'

`gnuplot-insertions-y-axis'

`gnuplot-insertions-z-axis'

`gnuplot-insertions-x2-axis'

`gnuplot-insertions-y2-axis'

`gnuplot-insertions-parametric-plots'

`gnuplot-insertions-polar-plots'

`gnuplot-insertions-surface-plots'

These variables can be customized by the user. For example, there are

many terminal types which are not in the terminal submenu but which

may be compiled into your copy of gnuplot.

Each of these variables is a list whose first element is a string and

all the rest are vectors as described in the document string for

`easy-menu-define'. The callback used throughout these menus is

`gnuplot-insert' which inserts the appropriate set expression and,

optionally, looks up that item in the gnuplot info file.

The easiest way to customize the submenus is to use the custom

package. Just type \\[gnuplot-customize] and follow your nose.

You can also add new items to any of these sub-menus by adding to the

`with-eval-after-load' blocks in your .emacs file. Here is an example of

adding the \"regis\" terminal type to the terminal sub-menu:

(with-eval-after-load \\='gnuplot

(setq gnuplot-insertions-terminal

(append gnuplot-insertions-terminal

(list

[\"regis\"

(gnuplot-insert \"set terminal regis\")

t]))))")

(defcustom gnuplot-insertions-show-help-flag nil

"Non-nil means to display certain help messages automatically.

These messages are shown after menu insertion of gnuplot commands."

:type 'boolean)

(defcustom gnuplot-insertions-menu-flag t

"Non-nil means to place the insertion menu in the menubar.

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type 'boolean)

(defvar gnuplot-insertions-top

'("insert set expression" "---")

"Top part of insertions menu.

See the document string for `gnuplot--insertions-menu'")

(defcustom gnuplot-insertions-adornments ; this is icky...

'("adornments"

["arrow" (gnuplot-insert "set arrow ") t]

["bar" (gnuplot-insert "set bar") t]

["border" (gnuplot-insert "set border") t]

["boxwidth" (gnuplot-insert "set boxwidth ") t]

["format" (gnuplot-insert "set format ") t]

["grid" (gnuplot-insert "set grid") t]

["key" (gnuplot-insert "set key ") t]

["label" (gnuplot-insert "set label ") t]

["pointsize" (gnuplot-insert "set pointsize ") t]

["samples" (gnuplot-insert "set samples ") t]

["size" (gnuplot-insert "set size ") t]

["style" (gnuplot-insert "set style ") t]

["tics" (gnuplot-insert "set tics ") t]

["timefmt" (gnuplot-insert "set timefmt ") t]

["timestamp" (gnuplot-insert "set timestamp ") t]

["title" (gnuplot-insert "set title ") t]

["zeroaxis" (gnuplot-insert "set zeroaxis") t])

"Adornments submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-plot-options

'("plot options"

["autoscale" (gnuplot-insert "set autoscale ") t]

["clip" (gnuplot-insert "set clip ") t]

["encoding" (gnuplot-insert "set encoding ") t]

["locale" (gnuplot-insert "set locale ") t]

["logscale" (gnuplot-insert "set logscale ") t]

["multiplot" (gnuplot-insert "set multiplot") t]

["missing" (gnuplot-insert "set missing \"\"") t]

["palette" (gnuplot-insert "set palette ") t]

["pm3d" (gnuplot-insert "set pm3d ") t]

["offsets" (gnuplot-insert "set offsets ") t]

["output" (gnuplot-insert "set output ") t]

["zero" (gnuplot-insert "set zero ") t])

"Plot options submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-terminal

'("terminal"

["eepic" (gnuplot-insert "set terminal eepic") t]

["fig" (gnuplot-insert "set terminal fig") t]

["gpic" (gnuplot-insert "set terminal gpic") t]

["latex" (gnuplot-insert "set terminal latex") t]

["linux" (gnuplot-insert "set terminal linux") t]

["pbm" (gnuplot-insert "set terminal pbm") t]

["png" (gnuplot-insert "set terminal png") t]

["postscript" (gnuplot-insert "set terminal postscript") t]

["pslatex" (gnuplot-insert "set terminal pslatex") t]

["table" (gnuplot-insert "set terminal table") t]

["tek40xx" (gnuplot-insert "set terminal tek40xx") t]

["tkcanvas" (gnuplot-insert "set terminal tkcanvas") t]

["tpic" (gnuplot-insert "set terminal tpic") t]

["vgagl" (gnuplot-insert "set terminal vgagl") t] ; for pm3d patch

["vttek" (gnuplot-insert "set terminal vttek") t]

["x11" (gnuplot-insert "set terminal x11") t])

"Terminal submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-x-axis

'("x-axis"

["xdata" (gnuplot-insert "set xdata ") t]

["xlabel" (gnuplot-insert "set xlabel ") t]

["xrange" (gnuplot-insert "set xrange [:]") t]

["xtics" (gnuplot-insert "set xtics ") t]

["mxtics" (gnuplot-insert "set mxtics ") t]

["xzeroaxis" (gnuplot-insert "set xzeroaxis ") t]

["xdtics" (gnuplot-insert "set xdtics ") t]

["xmtics" (gnuplot-insert "set xmtics ") t])

"X-axis submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-x2-axis

'("x2-axis"

["x2data" (gnuplot-insert "set xdata ") t]

["x2label" (gnuplot-insert "set xlabel ") t]

["x2range" (gnuplot-insert "set xrange [:]") t]

["x2tics" (gnuplot-insert "set xtics ") t]

["mx2tics" (gnuplot-insert "set mxtics ") t]

["x2zeroaxis" (gnuplot-insert "set xzeroaxis ") t]

["x2dtics" (gnuplot-insert "set xdtics ") t]

["x2mtics" (gnuplot-insert "set xmtics ") t])

"X2-axis submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-y-axis

'("y-axis"

["ydata" (gnuplot-insert "set ydata ") t]

["ylabel" (gnuplot-insert "set ylabel ") t]

["ymtics" (gnuplot-insert "set ymtics ") t]

["yrange" (gnuplot-insert "set yrange [:]") t]

["ytics" (gnuplot-insert "set ytics ") t]

["yzeroaxis" (gnuplot-insert "set yzeroaxis ") t]

["ydtics" (gnuplot-insert "set ydtics ") t]

["mytics" (gnuplot-insert "set mytics ") t])

"Y-axis submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-y2-axis

'("y2-axis"

["y2data" (gnuplot-insert "set ydata ") t]

["y2label" (gnuplot-insert "set ylabel ") t]

["y2range" (gnuplot-insert "set yrange [:]") t]

["y2tics" (gnuplot-insert "set ytics ") t]

["my2tics" (gnuplot-insert "set mytics ") t]

["y2zeroaxis" (gnuplot-insert "set yzeroaxis ") t]

["y2mtics" (gnuplot-insert "set ymtics ") t]

["y2dtics" (gnuplot-insert "set ydtics ") t])

"Y2-axis submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-z-axis

'("z-axis"

["zdata" (gnuplot-insert "set zdata ") t]

["zlabel" (gnuplot-insert "set zlabel ") t]

["zrange" (gnuplot-insert "set zrange [:]") t]

["ztics" (gnuplot-insert "set ztics ") t]

["mztics" (gnuplot-insert "set mztics ") t]

["zdtics" (gnuplot-insert "set zdtics ") t]

["zmtics" (gnuplot-insert "set zmtics ") t])

"Z-axis submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-parametric-plots

'("parametric plots"

["parametric" (gnuplot-insert "set parametric") t]

["isosamples" (gnuplot-insert "set isosamples ") t]

["dummy" (gnuplot-insert "set dummy ") t]

["trange" (gnuplot-insert "set trange [:]") t]

["urange" (gnuplot-insert "set urange [:]") t]

["vrange" (gnuplot-insert "set vrange [:]") t])

"Parametric plots submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-polar-plots

'("polar plots"

["polar" (gnuplot-insert "set polar") t]

["angles" (gnuplot-insert "set angles ") t]

["rrange" (gnuplot-insert "set rrange [:]") t])

"Polar plots submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defcustom gnuplot-insertions-surface-plots

'("surface plots"

["clabel" (gnuplot-insert "set clabel ") t]

["cntrparam" (gnuplot-insert "set cntrparam ") t]

["contour" (gnuplot-insert "set contour") t]

["dgrid3d" (gnuplot-insert "set dgrid3d ") t]

["hidden3d" (gnuplot-insert "set hidden3d ") t]

["mapping" (gnuplot-insert "set mapping ") t]

["surface" (gnuplot-insert "set surface ") t]

["view" (gnuplot-insert "set view ") t])

"Surface plots submenu in the insertions menu.

See the document string for `gnuplot--insertions-menu'

Changing this will not effect a change in any currently existing

`gnuplot-mode' buffer. You will see the change the next time you

create a `gnuplot-mode' buffer."

:type '(list (string :tag "Title")

(repeat :inline t

(vector (string :tag "Name")

(function :tag "Callback")

(boolean :tag "Enabled" t)))))

(defvar gnuplot-insertions-bottom

'("---"

["Display of info with insertion" gnuplot-toggle-info-display

:style toggle :selected gnuplot-insertions-show-help-flag]

["Display GUI popup with insertion" gnuplot-gui-toggle-popup

:active t

:style toggle :selected gnuplot-gui-popup-flag])

"Bottom part of the insertions menu.

This part contains the toggle buttons for displaying info or

opening an argument-setting popup.")

(defvar gnuplot-recently-sent nil

"This is a record of the most recent kind of text sent to gnuplot.

It takes as its value nil, `line', `region', `buffer', or `file'. It is

useful for functions included in `gnuplot-after-plot-hook'.")

(defvar gnuplot-buffer nil

"The name of the buffer displaying the gnuplot process.")

(defvar gnuplot-process nil

"Variable holding the process handle.")

(defvar gnuplot--comint-recent-buffer nil

"The most recently plotted gnuplot script buffer.

This is used by the function that plot from the comint buffer. It is

reset every time something is plotted from a script buffer.")

(defvar gnuplot--process-frame nil

"The frame for displaying the gnuplot process.

This is used when `gnuplot-display-process' is equal to `frame'.")

(defvar gnuplot--info-frame nil)

;; with info-look, there is no need to carry this list around -- it

;; can be generated on the fly appropriate to the currently installed

;; version of gnuplot.info

(defvar gnuplot--info-keywords 'pending

"A list of keywords used in GNUPLOT.

These are set by `gnuplot--set-keywords-list' from the values in

`info-lookup-cache'.")



;;; --- key bindings and menus

(defvar-keymap gnuplot-mode-map

"C-c C-b" #'gnuplot-send-buffer-to-gnuplot

"C-c C-o" #'gnuplot-gui-set-options-and-insert

"C-c C-e" #'gnuplot-show-comint-buffer

"C-c C-f" #'gnuplot-send-file-to-gnuplot

"C-c C-d" #'gnuplot-info-lookup-symbol

"C-c C-i" #'gnuplot-insert-filename

"C-c C-j" #'gnuplot-forward-script-line

"C-c C-k" #'gnuplot-kill-comint-buffer

"C-c C-l" #'gnuplot-send-line-to-gnuplot

"C-c C-n" #'gnuplot-negate-option

"C-c C-r" #'gnuplot-send-region-to-gnuplot

"C-M-x" #'gnuplot-send-line-to-gnuplot

"C-c C-v" #'gnuplot-send-line-and-forward

"C-c C-z" #'gnuplot-customize

"}" #'gnuplot-electric-insert

"M-TAB" #'completion-at-point

"S-<mouse-2>" #'gnuplot-gui-set-options-and-insert)

(defvar gnuplot-mode-menu nil)

(defvar gnuplot--display-options-menu

(cl-flet ((make-image-setter (type)

`[,(concat (upcase type) " images")

(lambda () (interactive) (gnuplot-set-image-format ,type))

:style toggle

:selected (eq gnuplot-image-format ,type)]))

`("Display plot output"

["Externally" gnuplot-external-display-mode

:style toggle

:selected (null gnuplot-inline-image-mode)]

["In Comint buffer" gnuplot-inline-display-mode

:active (display-images-p)

:style toggle

:selected (eq gnuplot-inline-image-mode 'comint)]

["In dedicated buffer" gnuplot-dedicated-display-mode

:style toggle

:selected (eq gnuplot-inline-image-mode 'dedicated)]

"---"

,@(mapcar #'make-image-setter (list "png" "jpeg" "svg"))

["Other image type..." gnuplot-set-image-format])))

(defvar gnuplot--menu

`("Gnuplot"

["Send line to gnuplot" gnuplot-send-line-to-gnuplot t]

["Send line & move forward" gnuplot-send-line-and-forward (not (eobp))]

["Send region to gnuplot" gnuplot-send-region-to-gnuplot

(gnuplot--mark-active)]

["Send buffer to gnuplot" gnuplot-send-buffer-to-gnuplot t]

["Send file to gnuplot" gnuplot-send-file-to-gnuplot t]

"---"

,gnuplot--display-options-menu

["Contextual completion and help" gnuplot-context-sensitive-mode

:style toggle

:selected gnuplot-context-sensitive-mode]

["Echo area help (eldoc-mode)" eldoc-mode

:active gnuplot-context-sensitive-mode

:style toggle

:selected eldoc-mode]

"---"

["Insert filename at point" gnuplot-insert-filename t]

["Negate set option" gnuplot-negate-option t]

["Keyword help" gnuplot-info-lookup-symbol]

["Quick help for thing at point" gnuplot-context-help-at-point

gnuplot-context-sensitive-mode]

["Info documentation on thing at point"

gnuplot-context-info-at-point

gnuplot-context-sensitive-mode]

["Show gnuplot process buffer" gnuplot-show-comint-buffer t]

["Set arguments at point" gnuplot-gui-set-options-and-insert t]

["Swap plot/splot/fit lists in GUI" gnuplot-gui-swap-simple-complete t]

"---"

["Customize gnuplot" gnuplot-customize t]

"---"

["Kill gnuplot" gnuplot-kill-comint-buffer t])

"Menu for `gnuplot-mode'.")



;;; --- syntax colorization, syntax table

(defvar gnuplot-mode-abbrev-table)

(defvar gnuplot-mode-syntax-table

(let ((table (make-syntax-table)))

(modify-syntax-entry ?* "." table)

(modify-syntax-entry ?+ "." table)

(modify-syntax-entry ?- "." table)

(modify-syntax-entry ?/ "." table)

(modify-syntax-entry ?% "." table)

(modify-syntax-entry ?= "." table)

(modify-syntax-entry ?: "." table)

(modify-syntax-entry ?& "." table )

(modify-syntax-entry ?^ "." table )

(modify-syntax-entry ?| "." table )

(modify-syntax-entry ?& "." table )

(modify-syntax-entry ?? "." table )

(modify-syntax-entry ?~ "." table )

(modify-syntax-entry ?_ "w" table )

(modify-syntax-entry ?\" "." table)

(modify-syntax-entry ?\' "." table)

(modify-syntax-entry ?` "." table)

(modify-syntax-entry ?\\ "." table)

table)

"Syntax table in use in `gnuplot-mode' buffers.

This is the same as the standard syntax table except that ` and _

are word characters, and math operators are punctuation

characters.")

;; Macro to generate efficient regexps for keyword matching

;;

;; These regular expressions treat the gnuplot vocabulary as complete

;; words. Although gnuplot will recognise unique abbreviations, these

;; regular expressions will not.

(defmacro gnuplot--make-regexp (list)

"Macro to generate efficient regexps for keyword matching from LIST."

`(regexp-opt ,list 'words))

;; Lists of gnuplot keywords for syntax coloring etc.

(defvar gnuplot--keywords-builtin-functions

'("abs" "acosh" "acos" "arg" "asinh" "asin" "atan" "atanh" "atan2" "besj1"

"besj0" "besy1" "besy0" "ceil" "column" "cosh" "cos" "erfc" "erf" "exp"

"floor" "gamma" "ibeta" "igamma" "imag" "int" "inverf" "invnorm" "lgamma"

"log" "log10" "norm" "rand" "real" "sgn" "sinh" "sin" "sqrt" "tanh" "tan"

"tm_hour" "tm_mday" "tm_min" "tm_mon" "tm_sec" "tm_wday" "tm_yday" "tm_year"

"valid" "EllipticPi" "EllipticE" "EllipticK" "words" "word" "value"

"timecolumn" "substr" "strstrt" "strptime" "strlen" "stringcolumn"

"strftime" "sprintf" "lambertw" "gprintf" "exists" "defined" "columnhead")

"List of GNUPLOT built-in functions, as strings.

These are highlighted using `font-lock-function-name-face'.")

(defvar gnuplot--keywords-plotting

'("axes" "every" "index" "lw" "lt" "ls" "linestyle" "linetype" "linewidth"

"notitle" "pt" "ps" "pointsize" "pointtype" "smooth" "thru" "title" "using"

"with" "noautoscale" "volatile" "matrix" "nonuniform" "binary" "fillstyle"

"linecolor" "pointinterval" "nosurface" "nocontours" "nohidden3d")

"List of GNUPLOT keywords associated with plotting, as strings.

These are highlighted using `font-lock-type-face'.

This list does not include plotting styles -- for that, see

`gnuplot--keywords-plotting-styles'")

(defvar gnuplot--keywords-plotting-styles

'("boxerrorbars" "boxes" "boxxyerrorbars" "candlesticks" "dots" "errorbars"

"financebars" "fsteps" "histeps" "impulses" "lines" "linespoints" "points"

"steps" "vector" "xerrorbars" "xyerrorbars" "yerrorbars" "vectors"

"filledcurves" "labels" "rgbalpha" "rgbimage" "image" "circles" "pm3d"

"histograms" "xyerrorlines" "xerrorlines" "errorlines" "yerrorlines")

"List of GNUPLOT plotting styles, as strings.

These are highlighted using `font-lock-function-name-face'.")

(defvar gnuplot--keywords-misc

'("bind" "cd" "clear" "exit" "fit" "help" "history" "load" "pause" "print"

"pwd" "quit" "replot" "save" "set" "show" "unset" "if" "else" "do" "update"

"undefine" "test" "system" "raise" "lower" "eval" "shell" "reset" "reread"

"refresh" "call")

"List of GNUPLOT miscellaneous commands, as strings.

These are highlighted using `font-lock-constant-face'.")

(defvar gnuplot--keywords-negatable-options

'("arrow" "autoscale" "border" "clabel" "clip" "contour" "dgrid3d" "grid"

"hidden3d" "historysize" "key" "label" "linestyle" "logscale" "mouse"

"multiplot" "mx2tics" "mxtics" "my2tics" "mytics" "mztics" "offsets" "polar"

"surface" "timestamp" "title" "x2dtics" "x2mtics" "x2tics" "x2zeroaxis"

"xdtics" "xmtics" "xtics" "xzeroaxis" "y2dtics" "y2mtics" "y2tics"

"y2zeroaxis" "ydtics" "ymtics" "ytics" "yzeroaxis" "zdtics" "zmtics" "ztics"

"zzeroaxis")

"List of gnuplot options which can be negated using `gnuplot-negate-option'.")

(defvar gnuplot--negatable-options-regexp

(gnuplot--make-regexp gnuplot--keywords-negatable-options))

;; Set up colorization for gnuplot.

(defvar gnuplot-font-lock-keywords

`(; stuff in brackets

("\\[\\([^]]+\\)\\]" (1 'font-lock-constant-face))

;; variable/function definitions

("\\(\\(\\sw\\|\\s_\\)+\\s-*\\((\\s-*\\(\\sw\\|\\s_\\)*\\s-*\\(,\\s-*\\sw*\\)*\\s-*)\\)?\\s-*=\\)[^=]"

(1 'font-lock-variable-name-face))

;; built-in function names

(,(gnuplot--make-regexp gnuplot--keywords-builtin-functions)

(0 'font-lock-function-name-face))

;; reserved words associated with plotting

(,(gnuplot--make-regexp gnuplot--keywords-plotting)

(0 'font-lock-type-face))

(,(gnuplot--make-regexp gnuplot--keywords-plotting-styles)

(0 'font-lock-function-name-face))

;; (s)plot -- also thing (s)plotted

("\\<s?plot\\>" (0 'font-lock-keyword-face))

;; ("\\<s?plot\\s-+\\([^'\" ]+\\)[) \n,\\\\]"

;; (1 'font-lock-variable-name-face))

;; other common commands

(,(gnuplot--make-regexp gnuplot--keywords-misc)

(0 'font-lock-constant-face))

("!.*$" (0 'font-lock-constant-face))))

(defvar gnuplot-font-lock-defaults

'(gnuplot-font-lock-keywords

nil ; Use syntactic fontification

t ; Use case folding

nil ; No extra syntax

;; calls `gnuplot--beginning-of-continuation'

;; to find a safe place to begin syntactic highlighting

beginning-of-defun))

;; Some corner cases in Gnuplot's comment and string syntax are

;; difficult to handle accurately using Emacs's built-in syntax tables

;; and parser:

;;

;; - strings can continue over several lines, but only by using a

;; backslash to escape the newline

;;

;; - double-quoted strings can contain escaped quotes, \", and escaped

;; backslashes, \\; but in single-quoted strings the quote is

;; escaped by doubling it, '', and backslash is only special at

;; end-of-line

;;

;; - either type of string can end at newline without needing a

;; - closing delimiter

;;

;; - comments continue over continuation lines

;;

;; The following syntax-propertize rules should accurately mark string

;; and comment boundaries using the "generic string fence" and

;; "generic comment fence" syntax properties.

(defalias 'gnuplot--syntax-propertize

(syntax-propertize-rules

;; Double quoted strings

((rx

(group "\"")

(* (or (seq "\\" anything)

(not (any "\"" "\n"))))

(group (or "\"" "\n" buffer-end)))

(1 "|") (2 "|"))

;; Single quoted strings

((rx

(group "'")

(* (or (seq "\\" "\n")

"''"

(not (any "'" "\n"))))

(group (or "'" "\n" buffer-end)))

(1 "|") (2 "|"))

;; Comments

((rx

(group "#")

(* (or (seq "\\" "\n")

any))

(or (group "\n") buffer-end))

(1 "!") (2 "!"))))

(defun gnuplot--syntax-propertize-extend-region (start end)

"Expand the region to `syntax-propertize' for strings and comments.

Region range is START to END.

Ensures that the region being searched begins and ends outside of

any lines continued with a backslash.

This function is added to `syntax-propertize-extend-region-functions'

in `gnuplot-mode' buffers."

(let ((continuation-start

(min start

(gnuplot--point-at-beginning-of-continuation start)))

(continuation-end

(max end

(gnuplot--point-at-end-of-continuation end))))

(if (and (= continuation-start start)

(= continuation-end end))

nil

(cons continuation-start continuation-end))))

;; Parsing utilities to tell if we are inside a string or comment

(defun gnuplot--in-string (&optional where)

"Return non-nil if the text at WHERE is within a string.

If WHERE is omitted, defaults to text at point.

This is a simple wrapper for `syntax-ppss'."

(save-excursion

(let ((parse-state (syntax-ppss where)))

(nth 3 parse-state))))

(defun gnuplot--in-comment (&optional where)

"Return non-nil if the text at WHERE is within a comment.

If WHERE is omitted, defaults to text at point.

This is a simple wrapper for `syntax-ppss'."

(save-excursion

(let ((parse-state (syntax-ppss where)))

(nth 4 parse-state))))

(defun gnuplot--in-string-or-comment (&optional where)

"Return non-nil if the text at WHERE is within a string or comment.

If WHERE is omitted, defaults to text at point.

This is a simple wrapper for `syntax-ppss'."

(save-excursion

(let ((parse-state (syntax-ppss where)))

(or (nth 3 parse-state)

(nth 4 parse-state)))))



;;; --- functions for sending commands to gnuplot

(defun gnuplot--split-string (string)

"Break STRING at each carriage return, returning a list of lines."

(let ((list ()) (line "") (index 0))

(while (< index (length string))

(if (char-equal (elt string index) ?\n)

(setq list (append list (list line))

line "")

(setq line (concat line (char-to-string (elt string index)))))

(setq index (1+ index)))

list))

;; -- the calls to `sleep-for' are to allow enough time for gnuplot

;; to write to the buffer before the next line is inserted

;; -- note that the input string is split into lines and each line is

;; sent to gnuplot individually. this is a bit slow, but it puts

;; each line on the comint history.

(defun gnuplot-send-string-to-gnuplot (string text)

"Sends STRING to the gnuplot program.

If no gnuplot process exists, a new one is created. TEXT indicates

the type of text being sent to gnuplot and is typically one of

nil, `line', `region', `buffer', or `file'. TEXT may be useful for

functions in `gnuplot-after-plot-hook'. `gnuplot-after-plot-hook' is

called by this function after all of STRING is sent to gnuplot."

(gnuplot--make-comint-buffer) ; make sure a gnuplot buffer exists

(setq gnuplot--comint-recent-buffer (current-buffer))

;; Create a gnuplot frame if needed

(when (and (equal gnuplot-display-process 'frame)

(not (frame-live-p gnuplot--process-frame)))

(let ((frame (selected-frame)))

(setq gnuplot--process-frame (make-frame))

(select-frame gnuplot--process-frame)

(switch-to-buffer gnuplot-buffer)

(delete-other-windows)

(select-frame frame)))

(let ((list (gnuplot--split-string string)))

(with-current-buffer (get-buffer gnuplot-buffer)

(goto-char (point-max))

;; bruce asks: what is this next line for?

(set-marker (process-mark gnuplot-process) (point-marker))

(sleep-for (* 10 gnuplot-delay))

(while list

(insert (car list))

(comint-send-input)

(sleep-for gnuplot-delay)

(setq list (cdr list))

(goto-char (point-max))))

(cond ((equal gnuplot-display-process 'window)

(gnuplot--display-and-recenter-comint-buffer))

((equal gnuplot-display-process 'frame)

;;(raise-frame gnuplot--process-frame)

(with-selected-frame gnuplot--process-frame

(gnuplot--display-and-recenter-comint-buffer))))

(setq gnuplot-recently-sent text)

(run-hooks 'gnuplot-after-plot-hook)))