description = "Allure JUnit Platform Integration"

val agent: Configuration by configurations.creating

dependencies {

agent("org.aspectj:aspectjweaver")

api(project(":allure-java-commons"))

implementation("org.junit.jupiter:junit-jupiter-api")

implementation("org.junit.platform:junit-platform-launcher")

implementation(project(":allure-test-filter"))

testAnnotationProcessor("org.slf4j:slf4j-simple")

testAnnotationProcessor(project(":allure-descriptions-javadoc"))

testImplementation("io.github.glytching:junit-extensions")

testImplementation("org.assertj:assertj-core")

testImplementation("org.junit.jupiter:junit-jupiter-api")

testImplementation("org.junit.jupiter:junit-jupiter-params")

testImplementation("org.slf4j:slf4j-simple")

testImplementation(project(":allure-assertj"))

testImplementation(project(":allure-java-commons-test"))

testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine")

}

tasks.jar {

manifest {

attributes(mapOf(

"Automatic-Module-Name" to "io.qameta.allure.junitplatform"

))

}

from("src/main/services") {

into("META-INF/services")

}

}

tasks.test {

systemProperty("junit.jupiter.execution.parallel.enabled", "false")

useJUnitPlatform()

exclude("**/features/*")

doFirst {

jvmArgs("-javaagent:${agent.singleFile}")

}

}

val spiOffJar by tasks.creating(Jar::class) {

from(sourceSets.getByName("main").output)

classifier = "spi-off"

}

val spiOff by configurations.creating {

extendsFrom(configurations.getByName("compile"))

}

artifacts.add("archives", spiOffJar)

artifacts.add("spiOff", spiOffJar)