" Vim support file to detect file types

"

" Maintainer: The Vim Project <https://github.com/vim/vim>

" Last Change: 2026 May 29

" Former Maintainer: Bram Moolenaar <Bram@vim.org>

" If the filetype can be detected from extension or file name(the final path component),

" please update `ft_from_name` and `ft_from_ext` in `runtime/autoload/dist/ft.vim`.

" Otherwise add a new autocmd in this file.

" Listen very carefully, I will say this only once

if exists("did_load_filetypes")

finish

endif

let did_load_filetypes = 1

" Line continuation is used here, remove 'C' from 'cpoptions'

let s:cpo_save = &cpo

set cpo&vim

augroup filetypedetect

" Ignored extensions

if exists("*fnameescape")

au BufNewFile,BufRead ?\+.orig,?\+.bak,?\+.old,?\+.new,?\+.dpkg-dist,?\+.dpkg-old,?\+.dpkg-new,?\+.dpkg-bak,?\+.rpmsave,?\+.rpmnew,?\+.pacsave,?\+.pacnew

\ exe "doau filetypedetect BufRead " . fnameescape(expand("<afile>:r"))

au BufNewFile,BufRead *~

\ let s:name = expand("<afile>") |

\ let s:short = substitute(s:name, '\~\+$', '', '') |

\ if s:name != s:short && s:short != "" |

\ exe "doau filetypedetect BufRead " . fnameescape(s:short) |

\ endif |

\ unlet! s:name s:short

au BufNewFile,BufRead ?\+.in

\ if expand("<afile>:t") != "configure.in" |

\ exe "doau filetypedetect BufRead " . fnameescape(expand("<afile>:r")) |

\ endif

elseif &verbose > 0

echomsg "Warning: some filetypes will not be recognized because this version of Vim does not have fnameescape()"

endif

" Pattern used to match file names which should not be inspected.

" Currently finds compressed files.

if !exists("g:ft_ignore_pat")

let g:ft_ignore_pat = '\.\(Z\|gz\|bz2\|zip\|tgz\)$'

endif

" Function used for patterns that end in a star: don't set the filetype if the

" file name matches ft_ignore_pat.

" When using this, the entry should probably be further down below with the

" other StarSetf() calls.

func s:StarSetf(ft)

if expand("<amatch>") !~ g:ft_ignore_pat

exe 'setf ' . a:ft

endif

endfunc

" Vim help file, set ft explicitly, because 'modeline' might be off

au BufNewFile,BufRead */doc/*.txt

\ if getline('$') =~ '\%(^\|\s\)vim:\%(.*\%(:\|\s\)\)\?\%(ft\|filetype\)=help\%(:\|\s\|$\)'

\| setf help

\| endif

" Detect by name

au BufNewFile,BufRead * call dist#ft#DetectFromName()

" Abaqus or Trasys

au BufNewFile,BufRead *.inp call dist#ft#Check_inp()

" A2ps printing utility

au BufNewFile,BufRead */etc/a2ps.cfg,*/etc/a2ps/*.cfg,a2psrc,.a2psrc setf a2ps

" Ada (83, 9X, 95)

if has("vms")

au BufNewFile,BufRead *.gpr,*.ada_m,*.adc setf ada

else

au BufNewFile,BufRead *.gpr setf ada

endif

" Apache config file

au BufNewFile,BufRead .htaccess,*/etc/httpd/*.conf setf apache

au BufNewFile,BufRead */etc/apache2/sites-*/*.com setf apache

" ALSA configuration

au BufNewFile,BufRead .asoundrc,*/usr/share/alsa/alsa.conf,*/etc/asound.conf setf alsaconf

" APT config file

au BufNewFile,BufRead */.aptitude/config setf aptconf

" more generic pattern far down

" Arch Inventory file

au BufNewFile,BufRead .arch-inventory,=tagging-method setf arch

" atlas or kawasaki_as

au BufNewFile,BufRead *.as call dist#ft#FTas()

" Active Server Pages (with Visual Basic Script)

au BufNewFile,BufRead *.asa

\ if exists("g:filetype_asa") |

\ exe "setf " . g:filetype_asa |

\ else |

\ setf aspvbs |

\ endif

" Active Server Pages (with Perl or Visual Basic Script)

au BufNewFile,BufRead *.asp

\ if exists("g:filetype_asp") |

\ exe "setf " . g:filetype_asp |

\ elseif getline(1) . getline(2) . getline(3) =~? "perlscript" |

\ setf aspperl |

\ else |

\ setf aspvbs |

\ endif

" Grub (must be before pattern *.lst)

au BufNewFile,BufRead */boot/grub/menu.lst,*/boot/grub/grub.conf,*/etc/grub.conf setf grub

" Maxima, see:

" https://maxima.sourceforge.io/docs/manual/maxima_71.html#file_005ftype_005fmaxima

" Must be before the pattern *.mac.

" *.dem omitted - also used by gnuplot demos

" *.mc omitted - used by dist#ft#McSetf()

au BufNewFile,BufRead *.demo,*.dm{1,2,3,t},*.wxm,maxima-init.mac setf maxima

" ObjectScript routine or assembly

au BufNewFile,BufRead *.mac call dist#ft#FTmac()

" Assembly (all kinds)

" *.lst is not pure assembly, it has two extra columns (address, byte codes)

" *.[sS], *.[aA] usually Assembly - GNU

au BufNewFile,BufRead *.asm,*.[sS],*.[aA],*.lst call dist#ft#FTasm()

" BASIC or Visual Basic

au BufNewFile,BufRead *.bas call dist#ft#FTbas()

au BufNewFile,BufRead *.bi,*.bm call dist#ft#FTbas()

" Batch file for MSDOS. See dist#ft#FTsys for *.sys

" *.cmd is close to a Batch file, but on OS/2 Rexx files and TI linker command files also use *.cmd.

" lnk: `/* comment */`, `// comment`, and `--linker-option=value`

" rexx: `/* comment */`, `-- comment`

au BufNewFile,BufRead *.cmd

\ if join(getline(1, 20), "\n") =~ 'MEMORY\|SECTIONS\|\%(^\|\n\)--\S\|\%(^\|\n\)//'

\| setf lnk

\| elseif getline(1) =~ '^/\*'

\| setf rexx

\| else

\| setf dosbatch

\| endif

" ABB RAPID or Batch file for MSDOS.

au BufNewFile,BufRead *.sys call dist#ft#FTsys()

if has("fname_case")

au BufNewFile,BufRead *.Sys,*.SYS call dist#ft#FTsys()

endif

au BufNewFile,BufRead *.sysx setf rapid

if has("fname_case")

au BufNewFile,BufRead *.sysX,*.Sysx,*.SysX,*.SYSX,*.SYSx setf rapid

endif

" Batch file for 4DOS

au BufNewFile,BufRead *.btm call dist#ft#FTbtm()

" BIND configuration

" sudoedit uses namedXXXX.conf

au BufNewFile,BufRead named*.conf,rndc*.conf,rndc*.key setf named

" BIND zone

au BufNewFile,BufRead *.db call dist#ft#BindzoneCheck('')

" Blade

au BufNewFile,BufRead *.blade.php setf blade

" Bitbake

au BufNewFile,BufRead *.bb,*.bbappend,*.bbclass,*/build/conf/*.conf,*/meta{-*,}/conf/*.conf,*/project-spec/configs/*.conf setf bitbake

" Blkid cache file

au BufNewFile,BufRead */etc/blkid.tab,*/etc/blkid.tab.old setf xml

" Bazel (https://bazel.build) and Buck2 (https://buck2.build/)

au BufNewFile,BufRead *.bzl,*.bxl,*.bazel,WORKSPACE,WORKSPACE.bzlmod setf bzl

if has("fname_case")

" There is another check for BUILD and BUCK further below.

au BufNewFile,BufRead *.BUILD,BUILD,BUCK setf bzl

endif

" Bundle config

au BufNewFile,BufRead */.bundle/config setf yaml

" C or lpc

au BufNewFile,BufRead *.c call dist#ft#FTlpc()

au BufNewFile,BufRead *.lpc,*.ulpc setf lpc

" m17n database files. */m17n/* matches installed files, */.m17n.d/* matches

" per-user config files, */m17n-db/* matches the git repo. (must be before

" *.cs)

au BufNewFile,BufRead */{m17n,.m17n.d,m17n-db}/*.{ali,cs,dir,flt,fst,lnm,mic,mim,tbl} setf m17ndb

" Cdrdao TOC or LaTeX \tableofcontents files

au BufNewFile,BufRead *.toc

\ if getline(1) =~# '\\contentsline' |setf tex|else|setf cdrtoc|endif

" Cdrdao config

au BufNewFile,BufRead */etc/cdrdao.conf,*/etc/defaults/cdrdao,*/etc/default/cdrdao,.cdrdao setf cdrdaoconf

" Containers config files

au BufNewFile,BufRead */containers/containers.conf{,.d/*.conf} setf toml

au BufNewFile,BufRead */containers/containers.conf.modules/*.conf setf toml

au BufNewFile,BufRead */containers/registries.conf{,.d/*.conf} setf toml

au BufNewFile,BufRead */containers/storage.conf setf toml

" Cynlib

" .cc and .cpp files can be C++ or Cynlib.

au BufNewFile,BufRead *.cc

\ if exists("cynlib_syntax_for_cc")|setf cynlib|else|setf cpp|endif

au BufNewFile,BufRead *.cpp

\ if exists("cynlib_syntax_for_cpp")|setf cynlib|else|setf cpp|endif

" C++

if has("fname_case")

au BufNewFile,BufRead *.C,*.H if !&fileignorecase | setf cpp | endif

endif

" .h files can be C, C++, Ch, Objective-C, or Objective-C++.

" Set g_filetype_h to set a different filetype

au BufNewFile,BufRead *.h call dist#ft#FTheader()

" Changelog

au BufNewFile,BufRead changelog.Debian,changelog.dch,NEWS.Debian,NEWS.dch,*/debian/changelog

\ setf debchangelog

au BufNewFile,BufRead [cC]hange[lL]og

\ if getline(1) =~ '; urgency='

\| setf debchangelog

\| else

\| setf changelog

\| endif

au BufNewFile,BufRead NEWS

\ if getline(1) =~ '; urgency='

\| setf debchangelog

\| endif

" CHILL

au BufNewFile,BufRead *..ch setf chill

" Changes for WEB and CWEB or CHILL

au BufNewFile,BufRead *.ch call dist#ft#FTchange()

" Clang-format

au BufNewFile,BufRead .clang-format setf yaml

" Clang-tidy

au BufNewFile,BufRead .clang-tidy setf yaml

" Matplotlib

au BufNewFile,BufRead *.mplstyle,matplotlibrc setf yaml

" Clever or dtd

au BufNewFile,BufRead *.ent call dist#ft#FTent()

" Clipper, FoxPro, ABB RAPID or eviews

au BufNewFile,BufRead *.prg call dist#ft#FTprg()

if has("fname_case")

au BufNewFile,BufRead *.Prg,*.PRG call dist#ft#FTprg()

endif

" Cmake

au BufNewFile,BufRead CMakeLists.txt,*.cmake,*.cmake.in setf cmake

" Cmusrc

au BufNewFile,BufRead */.cmus/{autosave,rc,command-history,*.theme} setf cmusrc

au BufNewFile,BufRead */cmus/{rc,*.theme} setf cmusrc

" Cobol

" cobol or zope form controller python script? (heuristic)

au BufNewFile,BufRead *.cpy

\ if getline(1) =~ '^##' |

\ setf python |

\ else |

\ setf cobol |

\ endif

" Dockerfile; Podman uses the same syntax with name Containerfile

" Also see Dockerfile.* below.

au BufNewFile,BufRead Containerfile,Dockerfile,dockerfile,*.[dD]ockerfile setf dockerfile

" Enlightenment configuration files

au BufNewFile,BufRead *enlightenment/*.cfg setf c

" Eterm

au BufNewFile,BufRead *Eterm/*.cfg setf eterm

" Elixir or Euphoria

au BufNewFile,BufRead *.ex call dist#ft#ExCheck()

" Elixir

au BufNewFile,BufRead mix.lock,*.exs setf elixir

au BufNewFile,BufRead *.eex,*.leex setf eelixir

" Euphoria 3 or 4

au BufNewFile,BufRead *.eu,*.ew,*.exu,*.exw call dist#ft#EuphoriaCheck()

if has("fname_case")

au BufNewFile,BufRead *.EU,*.EW,*.EX,*.EXU,*.EXW call dist#ft#EuphoriaCheck()

endif

" Execline (s6) scripts

au BufNewFile,BufRead *s6*/\(up\|down\|run\|finish\) setf execline

" Faust

au BufNewFile,BufRead *.dsp call dist#ft#FTdsp()

" Modula-3 configuration language (must be before *.cfg and *makefile)

au BufNewFile,BufRead *.quake,cm3.cfg setf m3quake

au BufNewFile,BufRead m3makefile,m3overrides setf m3build

" Many tools written in Python use dosini as their config

" like setuptools, pudb, coverage, pypi, gitlint, oelint-adv, pylint, bpython, mypy

" (must be before *.cfg)

au BufNewFile,BufRead {.,}pylintrc,*/bpython/config,*/mypy/config setf dosini

" Many tools written in Python use toml as their config, like black

au BufNewFile,BufRead black

\ if getline(1) =~ 'tool.back'

\| setf toml

\| endif

" LXQt's programs use dosini as their config

au BufNewFile,BufRead */{lxqt,screengrab}/*.conf setf dosini

" Quake

au BufNewFile,BufRead *baseq[2-3]/*.cfg,*id1/*.cfg setf quake

au BufNewFile,BufRead *quake[1-3]/*.cfg setf quake

" LaTeX packages use LaTeX as their configuration, such as:

" ~/.texlive/texmf-config/tex/latex/hyperref/hyperref.cfg

" ~/.texlive/texmf-config/tex/latex/docstrip/docstrip.cfg

au BufNewFile,BufRead */tex/latex/**.cfg setf tex

" Configure files

au BufNewFile,BufRead *.cfg call dist#ft#FTcfg()

if has("fname_case")

au BufNewFile,BufRead *.Cfg,*.CFG call dist#ft#FTcfg()

endif

" Debian autopkgtest

au BufNewFile,BufRead */debian/tests/control setf autopkgtest

" Debian Control

au BufNewFile,BufRead */{debian,DEBIAN}/control setf debcontrol

au BufNewFile,BufRead control

\ if getline(1) =~ '^Source:\|^Package:'

\| setf debcontrol

\| elseif getline(1) =~ '^Tests:\|^Test-Command:'

\| setf autopkgtest

\| endif

" Debian Copyright

au BufNewFile,BufRead */debian/copyright setf debcopyright

au BufNewFile,BufRead copyright

\ if getline(1) =~ '^Format:'

\| setf debcopyright

\| endif

" Debian Sources.list

au BufNewFile,BufRead */etc/apt/sources.list setf debsources

au BufNewFile,BufRead */etc/apt/sources.list.d/*.list setf debsources

au BufNewFile,BufRead */etc/apt/sources.list.d/*.sources setf deb822sources

" dnsmasq(8) configuration files

au BufNewFile,BufRead */etc/dnsmasq.conf setf dnsmasq

" the D language or dtrace

au BufNewFile,BufRead */dtrace/*.d setf dtrace

au BufNewFile,BufRead *.d call dist#ft#DtraceCheck()

" Dictd config

au BufNewFile,BufRead dictd*.conf setf dictdconf

" DEP3 formatted patch files

au BufNewFile,BufRead */debian/patches/* call dist#ft#Dep3patch()

" Diff files

au BufNewFile,BufRead *.patch

\ if getline(1) =~# '^From [0-9a-f]\{40,\} Mon Sep 17 00:00:00 2001$' |

\ setf gitsendemail |

\ else |

\ setf diff |

\ endif

" Dircolors

au BufNewFile,BufRead .dir_colors,.dircolors,*/etc/DIR_COLORS setf dircolors

" Diva (with Skill) or InstallShield

au BufNewFile,BufRead *.rul

\ if getline(1).getline(2).getline(3).getline(4).getline(5).getline(6) =~? 'InstallShield' |

\ setf ishd |

\ else |

\ setf diva |

\ endif

" DCL (Digital Command Language - vms) or DNS zone file

au BufNewFile,BufRead *.com call dist#ft#BindzoneCheck('dcl')

" Dune

au BufNewFile,BufRead jbuild,dune,dune-project,dune-workspace,dune-file setf dune

" Microsoft Module Definition or Modula-2

au BufNewFile,BufRead *.def call dist#ft#FTdef()

if has("fname_case")

au BufNewFile,BufRead *.DEF setf modula2

endif

" dsl: DSSSL or Structurizr

au BufNewFile,BufRead *.dsl

\ if getline(1) =~ '^\s*<\!' |

\ setf dsl |

\ else |

\ setf structurizr |

\ endif

" EDIF (*.edf,*.edif,*.edn,*.edo) or edn

au BufNewFile,BufRead *.ed\(f\|if\|o\) setf edif

au BufNewFile,BufRead *.edn

\ if getline(1) =~ '^\s*(\s*edif\>' |

\ setf edif |

\ else |

\ setf clojure |

\ endif

" Eiffel or Specman or Euphoria

au BufNewFile,BufRead *.e,*.E call dist#ft#FTe()

" Elm Filter Rules file

au BufNewFile,BufRead filter-rules setf elmfilt

" Erlang Application Resource Files

au BufNewFile,BufRead *.app.src setf erlang

au BufNewFile,BufRead *.app call dist#ft#FTapp()

" ESMTP rc file

au BufNewFile,BufRead *esmtprc setf esmtprc

" Fennel

au BufNewFile,BufRead {,.}fennelrc setf fennel

" Flatpak config

au BufNewFile,BufRead */flatpak/repo/config setf dosini

" Fortran

if has("fname_case")

au BufNewFile,BufRead *.F,*.FOR,*.FPP,*.FTN,*.F77,*.F90,*.F95,*.F03,*.F08 setf fortran

endif

au BufNewFile,BufRead *.for,*.fortran,*.fpp,*.ftn,*.f77,*.f90,*.f95,*.f03,*.f08 setf fortran

" Fortran or Forth

au BufNewFile,BufRead *.f call dist#ft#FTf()

" F# or Forth

au BufNewFile,BufRead *.fs call dist#ft#FTfs()

" GDB command files

au BufNewFile,BufRead .gdbinit,gdbinit,.cuda-gdbinit,cuda-gdbinit,.gdbearlyinit,gdbearlyinit,*.gdb setf gdb

" Gedcom

au BufNewFile,BufRead *.ged,lltxxxxx.txt setf gedcom

" Git

au BufNewFile,BufRead *.git/config,.gitconfig,*/etc/gitconfig setf gitconfig

au BufNewFile,BufRead */.config/git/config setf gitconfig

au BufNewFile,BufRead *.git/config.worktree setf gitconfig

au BufNewFile,BufRead *.git/worktrees/*/config.worktree setf gitconfig

au BufNewFile,BufRead .gitmodules,*.git/modules/*/config setf gitconfig

if exists('$XDG_CONFIG_HOME')

au BufNewFile,BufRead $XDG_CONFIG_HOME/git/config setf gitconfig

au BufNewFile,BufRead $XDG_CONFIG_HOME/git/attributes setf gitattributes

au BufNewFile,BufRead $XDG_CONFIG_HOME/git/ignore setf gitignore

endif

au BufNewFile,BufRead .gitattributes,*.git/info/attributes setf gitattributes

au BufNewFile,BufRead */.config/git/attributes setf gitattributes

au BufNewFile,BufRead */etc/gitattributes setf gitattributes

au BufNewFile,BufRead .gitignore,*.git/info/exclude setf gitignore

au BufNewFile,BufRead */.config/git/ignore,*.prettierignore setf gitignore

au BufNewFile,BufRead */.config/fd/ignore,.fdignore,.ignore setf gitignore

au BufNewFile,BufRead .rgignore,.dockerignore,.containerignore setf gitignore

au BufNewFile,BufRead .npmignore,.vscodeignore setf gitignore

au BufNewFile,BufRead git-rebase-todo setf gitrebase

au BufNewFile,BufRead .gitsendemail.msg.?????? setf gitsendemail

au BufNewFile,BufRead *.git/*

\ if getline(1) =~# '^\x\{40,\}\>\|^ref: ' |

\ setf git |

\ endif

" Gkrellmrc

au BufNewFile,BufRead gkrellmrc,gkrellmrc_? setf gkrellmrc

" GP scripts (2.0 and onward)

au BufNewFile,BufRead *.gp,.gprc setf gp

" GPG

au BufNewFile,BufRead */.gnupg/options setf gpg

au BufNewFile,BufRead */.gnupg/gpg.conf setf gpg

au BufNewFile,BufRead */usr/*/gnupg/options.skel setf gpg

if !empty($GNUPGHOME)

au BufNewFile,BufRead $GNUPGHOME/options setf gpg

au BufNewFile,BufRead $GNUPGHOME/gpg.conf setf gpg

endif

" Gitolite

au BufNewFile,BufRead {,.}gitolite.rc,example.gitolite.rc setf perl

" Gnuplot scripts

au BufNewFile,BufRead *.gpi,*.gnuplot,.gnuplot_history setf gnuplot

" GNU Radio Companion files

au BufNewFile,BufRead *.grc

\ if getline(1) =~# '<?xml' |

\ setf xml |

\ else |

\ setf yaml |

\ endif

" Groovy

au BufNewFile,BufRead *.gradle,*.groovy,Jenkinsfile setf groovy

" Group file

au BufNewFile,BufRead */etc/group,*/etc/group-,*/etc/group.edit,*/etc/gshadow,*/etc/gshadow-,*/etc/gshadow.edit,*/var/backups/group.bak,*/var/backups/gshadow.bak setf group

" Hare

au BufNewFile,BufRead README call dist#ft#FTharedoc()

" Haskell

au BufNewFile,BufRead */{.,}cabal/config setf cabalconfig

au BufNewFile,BufRead cabal.config setf cabalconfig

au BufNewFile,BufRead *.persistentmodels setf haskellpersistent

" Tilde (must be before HTML)

au BufNewFile,BufRead *.t.html setf tilde

" Translate shell

au BufNewFile,BufRead init.trans,*/etc/translate-shell,.trans setf clojure

" HTML (.stm for server side, .shtml is server-side or superhtml)

au BufNewFile,BufRead *.html,*.htm,*.shtml,*.stm call dist#ft#FThtml()

" Host config

au BufNewFile,BufRead */etc/host.conf setf hostconf

" Hosts access

au BufNewFile,BufRead */etc/hosts.allow,*/etc/hosts.deny setf hostsaccess

" Hy

au BufNewFile,BufRead *.hy,.hy-history setf hy

" Hyprland Configuration language

au BufNewFile,BufRead */hypr/*.conf,hypr\(land\|paper\|idle\|lock\).conf setf hyprlang

" i3

au BufNewFile,BufRead */i3/config setf i3config

au BufNewFile,BufRead */.i3/config setf i3config

" sway

au BufNewFile,BufRead */sway/config setf swayconfig

au BufNewFile,BufRead */sway/config.d/* setf swayconfig

au BufNewFile,BufRead */.sway/config setf swayconfig

" IDL (Interface Description Language)

au BufNewFile,BufRead *.idl call dist#ft#FTidl()

" Icewm menu

au BufNewFile,BufRead */.icewm/menu setf icemenu

" Indent profile (must come before IDL *.pro!)

au BufNewFile,BufRead indent.pro call dist#ft#ProtoCheck('indent')

" IDL (Interactive Data Language), Prolog, Cproto or zsh module C

au BufNewFile,BufRead *.pro call dist#ft#ProtoCheck('idlang')

" Initng

au BufNewFile,BufRead */etc/initng/*/*.i,*.ii setf initng

" Intel HEX or ObjectScript routine

au BufNewFile,BufRead *.int call dist#ft#FTint()

" Innovation Data Processing

au BufNewFile,BufRead upstream.dat\c,upstream.*.dat\c,*.upstream.dat\c setf upstreamdat

au BufNewFile,BufRead fdrupstream.log,upstream.log\c,upstream.*.log\c,*.upstream.log\c,UPSTREAM-*.log\c setf upstreamlog

au BufNewFile,BufRead upstreaminstall.log\c,upstreaminstall.*.log\c,*.upstreaminstall.log\c setf upstreaminstalllog

au BufNewFile,BufRead usserver.log\c,usserver.*.log\c,*.usserver.log\c setf usserverlog

au BufNewFile,BufRead usw2kagt.log\c,usw2kagt.*.log\c,*.usw2kagt.log\c setf usw2kagtlog

" Java Properties resource file (note: doesn't catch font.properties.pl)

au BufNewFile,BufRead *.properties,*.properties_??,*.properties_??_?? setf jproperties

" Eclipse preference files use Java Properties syntax

au BufNewFile,BufRead org.eclipse.*.prefs setf jproperties

" JSONC (JSON with comments)

au BufNewFile,BufRead *.jsonc,.babelrc,.eslintrc,.jsfmtrc,bun.lock setf jsonc

au BufNewFile,BufRead .jshintrc,.jscsrc,.vsconfig,.hintrc,.swrc,[jt]sconfig*.json setf jsonc

" Visual Studio Code settings

au BufNewFile,BufRead ~/*/{Code,VSCodium}/User/*.json setf jsonc

" Just

au BufNewFile,BufRead \c{,*.}justfile,\c*.just setf just

" Kitty

au BufNewFile,BufRead kitty.conf,*/kitty/*.conf setf kitty

" Kuka Robot Language

au BufNewFile,BufRead *.src call dist#ft#FTsrc()

au BufNewFile,BufRead *.dat call dist#ft#FTdat()

au BufNewFile,BufRead *.sub setf krl

if has("fname_case")

au BufNewFile,BufRead *.Src,*.SRC call dist#ft#FTsrc()

au BufNewFile,BufRead *.Dat,*.DAT call dist#ft#FTdat()

au BufNewFile,BufRead *.Sub,*.SUB setf krl

endif

" Lalrpop

au BufNewFile,Bufread *.lalrpop setf lalrpop

" Larch Shared Language

au BufNewFile,BufRead .lsl call dist#ft#FTlsl()

" Limits

au BufNewFile,BufRead */etc/limits,*/etc/*limits.conf,*/etc/*limits.d/*.conf setf limits

" LambdaProlog or SML (see dist#ft#FTmod for *.mod)

au BufNewFile,BufRead *.sig call dist#ft#FTsig()

" Ld loader

au BufNewFile,BufRead *.ld,*/ldscripts/* setf ld

" Libao

au BufNewFile,BufRead */etc/libao.conf,*/.libao setf libao

" Libsensors

au BufNewFile,BufRead */etc/sensors.conf,*/etc/sensors3.conf setf sensors

" LFTP

au BufNewFile,BufRead lftp.conf,.lftprc,*lftp/rc setf lftp

" Lifelines, LLVM, or Lex for C++

au BufNewFile,BufRead *.ll call dist#ft#FTll()

" Lisp (*.el = ELisp)

" *.jl was removed, it's also used for Julia, better skip than guess wrong.

if has("fname_case")

au BufNewFile,BufRead *.lsp,*.lisp,*.asd,*.el,*.L,.emacs,.sawfishrc setf lisp

else

au BufNewFile,BufRead *.lsp,*.lisp,*.asd,*.el,.emacs,.sawfishrc setf lisp

endif

" *.cl = Common Lisp or OpenCL

au BufNewFile,BufRead *.cl call dist#ft#FTcl()

" LiteStep RC files

au BufNewFile,BufRead */LiteStep/*/*.rc setf litestep

" Login access

au BufNewFile,BufRead */etc/login.access setf loginaccess

" Login defs

au BufNewFile,BufRead */etc/login.defs setf logindefs

" LOTOS or LaTeX \listoftables files

au BufNewFile,BufRead *.lot

\ if getline(1) =~# '\\contentsline' |setf tex|else|setf lotos|endif

" Lua, Texlua

au BufNewFile,BufRead *.lua,*.tlu,.lua_history setf lua

" Luarocks

au BufNewFile,BufRead *.rockspec,rock_manifest setf lua

" Linden Scripting Language (Second Life)

au BufNewFile,BufRead *.lsl call dist#ft#FTlsl()

" M4

au BufNewFile,BufRead *.m4 call dist#ft#FTm4()

au BufNewFile,BufRead .m4_history setf m4

" Mail (for Elm, trn, mutt, muttng, rn, slrn, neomutt)

au BufNewFile,BufRead snd.\d\+,.letter,.letter.\d\+,.followup,.article,.article.\d\+,pico.\d\+,mutt{ng,}-*-\w\+,mutt[[:alnum:]_-]\\\{6\},neomutt-*-\w\+,neomutt[[:alnum:]_-]\\\{6\},ae\d\+.txt,/tmp/SLRN[0-9A-Z.]\+,*.eml setf mail

" Mail aliases

au BufNewFile,BufRead */etc/mail/aliases,*/etc/aliases setf mailaliases

" Makefile

au BufNewFile,BufRead *[mM]akefile,*.mk,*.mak call dist#ft#FTmake()

au BufNewFile,BufRead Kbuild setf make

" Man config

au BufNewFile,BufRead */etc/man.conf,man.config setf manconf

" Map (UMN mapserver config file)

au BufNewFile,BufRead *.map

\ if getline(1) =~ '^\*\+$' |

\ setf lnkmap |

\ else |

\ setf map |

\ endif

" Markdown

au BufNewFile,BufRead *.markdown,*.mdown,*.mkd,*.mkdn,*.mdwn,*.md

\ if exists("g:filetype_md") |

\ exe "setf " . g:filetype_md |

\ else |

\ setf markdown |

\ endif

" Mathematica, Matlab, Murphi, Objective C or Octave

au BufNewFile,BufRead *.m call dist#ft#FTm()

" mbsync

au BufNewFile,BufRead *.mbsyncrc,isyncrc setf mbsync

" Mercurial (hg) commit file

au BufNewFile,BufRead hg-editor-*.txt setf hgcommit

" Mercurial config (looks like generic config file)

au BufNewFile,BufRead *.hgrc,*hgrc setf cfg

" MetaPost

au BufNewFile,BufRead *.mpxl,*.mpiv,*.mpvi let b:mp_metafun = 1 | setf mp

" MMIX or VMS makefile

au BufNewFile,BufRead *.mms call dist#ft#FTmms()

" ABB Rapid, Modula-2, Modsim III or LambdaProlog

au BufNewFile,BufRead *.mod call dist#ft#FTmod()

if has("fname_case")

au BufNewFile,BufRead *.Mod,*.MOD call dist#ft#FTmod()

endif

au BufNewFile,BufRead *.modx setf rapid

if has("fname_case")

au BufNewFile,BufRead *.modX,*.Modx,*.ModX,*.MODX,*.MODx setf rapid

endif

" Modula-3 (.m3, .i3, .mg, .ig)

au BufNewFile,BufRead *.[mi][3g] setf modula3

" Modconf

au BufNewFile,BufRead */etc/modules.conf,*/etc/modules,*/etc/conf.modules setf modconf

" Mplayer config

au BufNewFile,BufRead mplayer.conf,*/.mplayer/config setf mplayerconf

" Mysql

au BufNewFile,BufRead *.mysql,.mysql_history setf mysql

" Tcl Shell RC file

" Vivado journal file records REPL input in tcl syntax

" Vivado log file records REPL input in tcl syntax and output

au BufNewFile,BufRead tclsh.rc,vivado*.{jou,log} setf tcl

" M$ Resource files

" /etc/Muttrc.d/file.rc is muttrc

au BufNewFile,BufRead *.rc,*.rch

\ if expand("<afile>") !~ "/etc/Muttrc.d/" |

\ setf rc |

\ endif

" Mojo

" Mojo files use either .mojo or .🔥 as extension

au BufNewFile,BufRead *.mojo,*.🔥 setf mojo

" Mutt setup file (also for Muttng)

au BufNewFile,BufRead Mutt{ng,}rc setf muttrc

" Neomutt log

au BufNewFile,BufRead *.neomuttdebug* setf neomuttlog

" Nano

au BufNewFile,BufRead */etc/nanorc,*.nanorc setf nanorc

" Nastran input/DMAP

"au BufNewFile,BufRead *.dat setf nastran

" Natural

au BufNewFile,BufRead *.NS[ACGLMNPS] setf natural

" Neofetch

au BufNewFile,BufRead */neofetch/config.conf setf sh

" Nginx

au BufNewFile,BufRead *.nginx,nginx*.conf,*nginx.conf,*/nginx/*.conf setf nginx

" Nroff/Groff/Troff (*.ms and *.t are checked below)

au BufNewFile,BufRead *.me

\ if expand("<afile>") != "read.me" && expand("<afile>") != "click.me" |

\ setf nroff |

\ endif

au BufNewFile,BufRead *.tr,*.nr,*.roff,*.tmac setf nroff

au BufNewFile,BufRead *.groff,*.mom setf groff

au BufNewFile,BufRead *.[0-9],*.[013]p,*.[1-8]x,*.3{am,perl,pm,posix,type},*.n call dist#ft#FTnroff()

" Nroff or Objective C++

au BufNewFile,BufRead *.mm call dist#ft#FTmm()

" notmuch

au BufNewFile,BufRead .notmuch-config{,.*} setf dosini

au BufNewFile,BufRead ~/.config/notmuch/*/config setf dosini

if exists('$XDG_CONFIG_HOME')

au BufNewFile,BufRead $XDG_CONFIG_HOME/notmuch/*/config setf dosini

endif

" OCaml

au BufNewFile,BufRead *.ml,*.mli,*.mll,*.mly,.ocamlinit,*.mlt,*.mlp,*.mlip,*.mli.cppo,*.ml.cppo setf ocaml

" Octave

au BufNewFile,BufRead octave.conf,.octaverc,octaverc,*/octave/history setf octave

" OPAM

au BufNewFile,BufRead opam,*.opam,*.opam.template,opam.locked,*.opam.locked setf opam

" OpenFOAM

au BufNewFile,BufRead fvSchemes,fvSolution,fvConstrains,fvModels,*/constant/g call dist#ft#FTfoam()

" OPL

au BufNewFile,BufRead *.[Oo][Pp][Ll] setf opl

" ini style config files, using # comments

au BufNewFile,BufRead */.aws/config,*/.aws/credentials,*/.aws/cli/alias setf confini

au BufNewFile,BufRead *.nmconnection setf confini

au BufNewFile,BufRead paru.conf setf confini

au BufNewFile,BufRead */{,.}gnuradio/*.conf setf confini

au BufNewFile,BufRead */gnuradio/conf.d/*.conf setf confini

" Pacman hooks

au BufNewFile,BufRead *.hook

\ if getline(1) == '[Trigger]' |

\ setf confini |

\ endif

" Pacman makepkg

au BufNewFile,BufRead {.,}makepkg.conf setf sh

" Pacman log

au BufRead pacman.log* call s:StarSetf('pacmanlog')

" Pam conf

au BufNewFile,BufRead */etc/pam.conf setf pamconf

" Password file

au BufNewFile,BufRead */etc/passwd,*/etc/passwd-,*/etc/passwd.edit,*/etc/shadow,*/etc/shadow-,*/etc/shadow.edit,*/var/backups/passwd.bak,*/var/backups/shadow.bak setf passwd

" Pascal or Puppet manifest

au BufNewFile,BufRead *.pp call dist#ft#FTpp()

" Xilinx labtools project file or Lazarus program file

au BufNewFile,BufRead *.lpr

\ if getline(1) =~# "<?xml" |

\ setf xml |

\ else |

\ setf pascal |

\ endif

" Perl or Prolog

if has("fname_case")

au BufNewFile,BufRead *.pl,*.PL call dist#ft#FTpl()

else

au BufNewFile,BufRead *.pl call dist#ft#FTpl()

endif

au BufNewFile,BufRead *.plx,*.al,*.psgi setf perl

" Perl, XPM or XPM2

au BufNewFile,BufRead *.pm

\ if getline(1) =~ "XPM2" |

\ setf xpm2 |

\ elseif getline(1) =~ "XPM" |

\ setf xpm |

\ else |

\ setf perl |

\ endif

" Php, php3, php4, etc.

" Also Phtml (was used for PHP 2 in the past).

" Also .ctp for Cake template file.

" Also .phpt for php tests.

" Also .theme for Drupal theme files.

au BufNewFile,BufRead *.php,*.php\d,*.phtml,*.ctp,*.phpt,*.theme setf php

" Pinfo config

au BufNewFile,BufRead */etc/pinforc,*/.pinforc setf pinfo

" Pip requirements

au BufNewFile,BufRead *-requirements.txt setf requirements

au BufNewFile,BufRead requirements-*.txt setf requirements

au BufNewFile,BufRead constraints.txt setf requirements

au BufNewFile,BufRead requirements.in setf requirements

au BufNewFile,BufRead requirements/*.txt setf requirements

au BufNewFile,BufRead requires/*.txt setf requirements

" Pkl

au BufNewFile,BufRead PklProject,*.pkl,*.pcf,pkl-lsp://* setf pkl

" WIC kickstarter files

au BufNewFile,BufRead *.wks,*.wks.in,*.wks.inc setf wks

" Povray, Pascal, PHP or assembly

au BufNewFile,BufRead *.inc call dist#ft#FTinc()

" PowerShell

au BufNewFile,BufRead *.ps1,*.psd1,*.psm1,*.pssc setf ps1

au BufNewFile,BufRead *.ps1xml setf ps1xml

au BufNewFile,BufRead *.cdxml,*.psc1 setf xml

" Printcap and Termcap

au BufNewFile,BufRead *printcap

\ let b:ptcap_type = "print" | setf ptcap

au BufNewFile,BufRead *termcap

\ let b:ptcap_type = "term" | setf ptcap

" Progress or CWEB

au BufNewFile,BufRead *.w call dist#ft#FTprogress_cweb()

" Progress or assembly or Swig

au BufNewFile,BufRead *.i call dist#ft#FTi()

" Progress or Pascal

au BufNewFile,BufRead *.p call dist#ft#FTprogress_pascal()

" Software Distributor Product Specification File (POSIX 1387.2-1995)

au BufNewFile,BufRead INDEX,INFO

\ if getline(1) =~ '^\s*\(distribution\|installed_software\|root\|bundle\|product\)\s*$' |

\ setf psf |

\ endif

" Protocols

au BufNewFile,BufRead */etc/protocols setf protocols

" Python, Python Shell Startup and Python Stub Files

" Quixote (Python-based web framework) and IPython

au BufNewFile,BufRead *.py,*.pyw,.pythonstartup,.pythonrc,.python_history,.jline-jython.history setf python

au BufNewFile,BufRead *.ipy,*.ptl,*.pyi,SConstruct setf python

" RCS file

au BufNewFile,BufRead *\,v setf rcs

" Registry for MS-Windows

au BufNewFile,BufRead *.reg

\ if getline(1) =~? '^REGEDIT[0-9]*\s*$\|^Windows Registry Editor Version \d*\.\d*\s*$' | setf registry | endif

" Ripgrep rc

au BufNewFile,BufRead {.,}ripgreprc setf conf

" R Help file

if has("fname_case")

au BufNewFile,BufRead *.rd,*.Rd setf rhelp

else

au BufNewFile,BufRead *.rd setf rhelp

endif

" R noweb file

if has("fname_case")

au BufNewFile,BufRead *.Rnw,*.rnw,*.Snw,*.snw setf rnoweb

else

au BufNewFile,BufRead *.rnw,*.snw setf rnoweb

endif

" R Markdown file

if has("fname_case")

au BufNewFile,BufRead *.Rmd,*.rmd,*.Smd,*.smd setf rmd

else

au BufNewFile,BufRead *.rmd,*.smd setf rmd

endif

" R reStructuredText file

if has("fname_case")

au BufNewFile,BufRead *.Rrst,*.rrst,*.Srst,*.srst setf rrst

else

au BufNewFile,BufRead *.rrst,*.srst setf rrst

endif

" Rexx, Rebol or R

au BufNewFile,BufRead *.r,*.R call dist#ft#FTr()

" Remind

au BufNewFile,BufRead .reminders,*.remind,*.rem setf remind

" Rantfile and Rakefile is like Ruby

au BufNewFile,BufRead [rR]antfile,*.rant,[rR]akefile,*.rake setf ruby

" Rust

au BufNewFile,BufRead Cargo.lock,*/.cargo/config,*/.cargo/credentials setf toml

" Sather, TI linear assembly

au BufNewFile,BufRead *.sa call dist#ft#FTsa()

" SuperCollider

au BufNewFile,BufRead *.sc call dist#ft#FTsc()

au BufNewFile,BufRead *.quark setf supercollider

" scdoc

au BufNewFile,BufRead *.scd call dist#ft#FTscd()

" Sendmail .mc files are actually m4. Could also be MS Message text file or