set_property(DIRECTORY . PROPERTY FOLDER "JavaScriptCore")

list(APPEND JavaScriptCore_UNIFIED_SOURCE_LIST_FILES

"Sources.txt"

)

set(JavaScriptCore_INCLUDE_DIRECTORIES

"${JavaScriptCore_FRAMEWORK_HEADERS_DIR}"

"${JavaScriptCore_PRIVATE_FRAMEWORK_HEADERS_DIR}"

)

set(JavaScriptCore_PRIVATE_INCLUDE_DIRECTORIES

"${CMAKE_BINARY_DIR}"

"${JavaScriptCore_PRIVATE_FRAMEWORK_HEADERS_DIR}/JavaScriptCore"

"${JAVASCRIPTCORE_DIR}"

"${JAVASCRIPTCORE_DIR}/API"

"${JAVASCRIPTCORE_DIR}/assembler"

"${JAVASCRIPTCORE_DIR}/b3"

"${JAVASCRIPTCORE_DIR}/b3/air"

"${JAVASCRIPTCORE_DIR}/bindings"

"${JAVASCRIPTCORE_DIR}/builtins"

"${JAVASCRIPTCORE_DIR}/bytecode"

"${JAVASCRIPTCORE_DIR}/bytecompiler"

"${JAVASCRIPTCORE_DIR}/dfg"

"${JAVASCRIPTCORE_DIR}/disassembler"

"${JAVASCRIPTCORE_DIR}/disassembler/ARM64"

"${JAVASCRIPTCORE_DIR}/disassembler/zydis"

"${JAVASCRIPTCORE_DIR}/domjit"

"${JAVASCRIPTCORE_DIR}/ftl"

"${JAVASCRIPTCORE_DIR}/fuzzilli"

"${JAVASCRIPTCORE_DIR}/heap"

"${JAVASCRIPTCORE_DIR}/debugger"

"${JAVASCRIPTCORE_DIR}/inspector"

"${JAVASCRIPTCORE_DIR}/inspector/agents"

"${JAVASCRIPTCORE_DIR}/inspector/augmentable"

"${JAVASCRIPTCORE_DIR}/inspector/remote"

"${JAVASCRIPTCORE_DIR}/interpreter"

"${JAVASCRIPTCORE_DIR}/jit"

"${JAVASCRIPTCORE_DIR}/llint"

"${JAVASCRIPTCORE_DIR}/lol"

"${JAVASCRIPTCORE_DIR}/parser"

"${JAVASCRIPTCORE_DIR}/profiler"

"${JAVASCRIPTCORE_DIR}/runtime"

"${JAVASCRIPTCORE_DIR}/runtime/temporal/core"

"${JAVASCRIPTCORE_DIR}/tools"

"${JAVASCRIPTCORE_DIR}/wasm"

"${JAVASCRIPTCORE_DIR}/wasm/debugger"

"${JAVASCRIPTCORE_DIR}/wasm/js"

"${JAVASCRIPTCORE_DIR}/yarr"

"${JavaScriptCore_DERIVED_SOURCES_DIR}"

"${JavaScriptCore_DERIVED_SOURCES_DIR}/inspector"

"${JavaScriptCore_DERIVED_SOURCES_DIR}/runtime"

"${JavaScriptCore_DERIVED_SOURCES_DIR}/yarr"

)

if (USE_CAPSTONE)

list(APPEND JavaScriptCore_PRIVATE_INCLUDE_DIRECTORIES "${THIRDPARTY_DIR}/capstone/Source/include")

endif ()

set(JavaScriptCore_OBJECT_LUT_SOURCES

runtime/ArrayConstructor.cpp

runtime/AsyncFromSyncIteratorPrototype.cpp

runtime/AsyncGeneratorPrototype.cpp

runtime/BigIntConstructor.cpp

runtime/BigIntPrototype.cpp

runtime/BooleanPrototype.cpp

runtime/DateConstructor.cpp

runtime/DatePrototype.cpp

runtime/ErrorPrototype.cpp

runtime/GeneratorPrototype.cpp

runtime/IntlCollatorConstructor.cpp

runtime/IntlCollatorPrototype.cpp

runtime/IntlDateTimeFormatConstructor.cpp

runtime/IntlDateTimeFormatPrototype.cpp

runtime/IntlDisplayNamesConstructor.cpp

runtime/IntlDisplayNamesPrototype.cpp

runtime/IntlDurationFormatConstructor.cpp

runtime/IntlDurationFormatPrototype.cpp

runtime/IntlListFormatConstructor.cpp

runtime/IntlListFormatPrototype.cpp

runtime/IntlLocalePrototype.cpp

runtime/IntlNumberFormatConstructor.cpp

runtime/IntlNumberFormatPrototype.cpp

runtime/IntlObject.cpp

runtime/IntlPluralRulesConstructor.cpp

runtime/IntlPluralRulesPrototype.cpp

runtime/IntlRelativeTimeFormatConstructor.cpp

runtime/IntlRelativeTimeFormatPrototype.cpp

runtime/IntlSegmentIteratorPrototype.cpp

runtime/IntlSegmenterConstructor.cpp

runtime/IntlSegmenterPrototype.cpp

runtime/IntlSegmentsPrototype.cpp

runtime/JSDataViewPrototype.cpp

runtime/JSGlobalObject.cpp

runtime/JSIterator.cpp

runtime/JSIteratorConstructor.cpp

runtime/JSIteratorHelperPrototype.cpp

runtime/JSONObject.cpp

runtime/JSPromiseConstructor.cpp

runtime/JSPromisePrototype.cpp

runtime/MapConstructor.cpp

runtime/MapPrototype.cpp

runtime/NumberConstructor.cpp

runtime/NumberPrototype.cpp

runtime/ObjectConstructor.cpp

runtime/ReflectObject.cpp

runtime/RegExpConstructor.cpp

runtime/RegExpPrototype.cpp

runtime/RegExpStringIteratorPrototype.cpp

runtime/SetPrototype.cpp

runtime/ShadowRealmObject.cpp

runtime/ShadowRealmPrototype.cpp

runtime/StringConstructor.cpp

runtime/StringPrototype.cpp

runtime/SymbolConstructor.cpp

runtime/SymbolPrototype.cpp

runtime/TemporalDurationConstructor.cpp

runtime/TemporalDurationPrototype.cpp

runtime/TemporalInstantConstructor.cpp

runtime/TemporalInstantPrototype.cpp

runtime/TemporalNow.cpp

runtime/TemporalObject.cpp

runtime/TemporalPlainDateConstructor.cpp

runtime/TemporalPlainDatePrototype.cpp

runtime/TemporalPlainDateTimeConstructor.cpp

runtime/TemporalPlainDateTimePrototype.cpp

runtime/TemporalPlainMonthDayConstructor.cpp

runtime/TemporalPlainMonthDayPrototype.cpp

runtime/TemporalPlainTimeConstructor.cpp

runtime/TemporalPlainTimePrototype.cpp

runtime/TemporalPlainYearMonthConstructor.cpp

runtime/TemporalPlainYearMonthPrototype.cpp

runtime/TemporalTimeZoneConstructor.cpp

runtime/TemporalTimeZonePrototype.cpp

runtime/TemporalZonedDateTimeConstructor.cpp

runtime/TemporalZonedDateTimePrototype.cpp

wasm/js/JSWebAssembly.cpp

wasm/js/WebAssemblyArrayConstructor.cpp

wasm/js/WebAssemblyArrayPrototype.cpp

wasm/js/WebAssemblyCompileErrorConstructor.cpp

wasm/js/WebAssemblyCompileErrorPrototype.cpp

wasm/js/WebAssemblyExceptionConstructor.cpp

wasm/js/WebAssemblyExceptionPrototype.cpp

wasm/js/WebAssemblyGlobalConstructor.cpp

wasm/js/WebAssemblyGlobalPrototype.cpp

wasm/js/WebAssemblyInstanceConstructor.cpp

wasm/js/WebAssemblyInstancePrototype.cpp

wasm/js/WebAssemblyLinkErrorConstructor.cpp

wasm/js/WebAssemblyLinkErrorPrototype.cpp

wasm/js/WebAssemblyMemoryConstructor.cpp

wasm/js/WebAssemblyMemoryPrototype.cpp

wasm/js/WebAssemblyModuleConstructor.cpp

wasm/js/WebAssemblyModulePrototype.cpp

wasm/js/WebAssemblyRuntimeErrorConstructor.cpp

wasm/js/WebAssemblyRuntimeErrorPrototype.cpp

wasm/js/WebAssemblySuspendErrorConstructor.cpp

wasm/js/WebAssemblySuspendErrorPrototype.cpp

wasm/js/WebAssemblyStructConstructor.cpp

wasm/js/WebAssemblyStructPrototype.cpp

wasm/js/WebAssemblyTableConstructor.cpp

wasm/js/WebAssemblyTablePrototype.cpp

wasm/js/WebAssemblyTagConstructor.cpp

wasm/js/WebAssemblyTagPrototype.cpp

)

list(APPEND JavaScriptCore_SOURCES

${JavaScriptCore_DERIVED_SOURCES_DIR}/JSCBuiltins.cpp

)

set(JavaScriptCore_FRAMEWORKS

WTF

bmalloc

)

if (USE_CAPSTONE)

list(APPEND JavaScriptCore_LIBRARIES capstone)

endif ()

if (ATOMICS_REQUIRE_LIBATOMIC)

list(APPEND JavaScriptCore_LIBRARIES atomic)

endif ()

set(JavaScriptCore_SCRIPTS_SOURCES_DIR "${JAVASCRIPTCORE_DIR}/Scripts")

# Globbing relies on the fact that generator-specific file names are prefixed with their directory.

# Top-level scripts should have a file extension, since they are invoked during the build.

set(JavaScriptCore_SCRIPTS_SOURCES_PATHS

${JavaScriptCore_SCRIPTS_SOURCES_DIR}/*.pl

${JavaScriptCore_SCRIPTS_SOURCES_DIR}/*.py

${JavaScriptCore_SCRIPTS_SOURCES_DIR}/wkbuiltins/builtins*.py

${JavaScriptCore_SCRIPTS_SOURCES_DIR}/wkbuiltins/wkbuiltins.py

)

# The directory flattening performed below mirrors what the Mac port does with private headers.

file(GLOB JavaScriptCore_SCRIPTS_SOURCES ${JavaScriptCore_SCRIPTS_SOURCES_PATHS})

foreach (_file ${JavaScriptCore_SCRIPTS_SOURCES})

get_filename_component(_script "${_file}" NAME)

add_custom_command(

OUTPUT ${JavaScriptCore_SCRIPTS_DIR}/${_script}

MAIN_DEPENDENCY ${_file}

WORKING_DIRECTORY ${JavaScriptCore_DERIVED_SOURCES_DIR}

COMMAND ${CMAKE_COMMAND} -E copy_if_different ${_file} ${JavaScriptCore_SCRIPTS_DIR}/${_script}

VERBATIM)

list(APPEND JavaScriptCore_SCRIPTS ${JavaScriptCore_SCRIPTS_DIR}/${_script})

endforeach ()

# This is the default build variant for Xcode builds.

set(BUILD_VARIANTS

"normal"

)

# Offline assembler arguments shared across settings extractor, offset extractor, and asm.rb.

set(OFFLINE_ASM_INCLUDE_DIRS "")

set(OFFLINE_ASM_ARGS "")

set(OFFLINE_ASM_FORMAT_ARGS "")

if (CMAKE_SYSTEM_NAME MATCHES "Linux")

list(APPEND OFFLINE_ASM_FORMAT_ARGS --binary-format=ELF)

endif ()

if (MSVC AND NOT ENABLE_C_LOOP)

list(APPEND OFFLINE_ASM_FORMAT_ARGS --platform=Windows)

endif ()

if (WEBKIT_ADDITIONS_INCLUDE_PATH AND EXISTS "${WEBKIT_ADDITIONS_INCLUDE_PATH}/WebKitAdditions/Additions")

list(APPEND OFFLINE_ASM_ARGS "--webkit-additions-path=${WEBKIT_ADDITIONS_INCLUDE_PATH}/WebKitAdditions")

if (EXISTS "${WEBKIT_ADDITIONS_INCLUDE_PATH}/WebKitAdditions/Additions/llint")

list(APPEND OFFLINE_ASM_INCLUDE_DIRS "-I${WEBKIT_ADDITIONS_INCLUDE_PATH}/WebKitAdditions/Additions/llint/")

endif ()

endif ()

set(LLINT_ASM

llint/InPlaceInterpreter.asm

llint/InPlaceInterpreter64.asm

llint/LowLevelInterpreter.asm

llint/LowLevelInterpreter32_64.asm

llint/LowLevelInterpreter64.asm

)

set(OFFLINE_ASM

offlineasm/arm.rb

offlineasm/arm64.rb

offlineasm/arm64e.rb

offlineasm/asm.rb

offlineasm/ast.rb

offlineasm/backends.rb

offlineasm/cloop.rb

offlineasm/config.rb

offlineasm/instructions.rb

offlineasm/offsets.rb

offlineasm/opt.rb

offlineasm/parser.rb

offlineasm/registers.rb

offlineasm/risc.rb

offlineasm/riscv64.rb

offlineasm/self_hash.rb

offlineasm/settings.rb

offlineasm/transform.rb

offlineasm/x86.rb

)

set(GENERATOR

generator/Argument.rb

generator/Assertion.rb

generator/Checkpoints.rb

generator/DSL.rb

generator/Fits.rb

generator/GeneratedFile.rb

generator/Metadata.rb

generator/Opcode.rb

generator/OpcodeGroup.rb

generator/Options.rb

generator/Section.rb

generator/Template.rb

generator/Type.rb

generator/Wasm.rb

generator/main.rb

)

add_custom_command(

OUTPUT ${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/InitBytecodes.asm ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeStructs.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeIndices.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeDumperGenerated.cpp

MAIN_DEPENDENCY ${JAVASCRIPTCORE_DIR}/generator/main.rb

DEPENDS ${GENERATOR} bytecode/BytecodeList.rb ${JAVASCRIPTCORE_DIR}/wasm/wasm.json

COMMAND ${Ruby_EXECUTABLE} ${JAVASCRIPTCORE_DIR}/generator/main.rb --bytecodes_h ${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h --init_bytecodes_asm ${JavaScriptCore_DERIVED_SOURCES_DIR}/InitBytecodes.asm --bytecode_structs_h ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeStructs.h --bytecode_indices_h ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeIndices.h ${JAVASCRIPTCORE_DIR}/bytecode/BytecodeList.rb --wasm_json ${JAVASCRIPTCORE_DIR}/wasm/wasm.json --bytecode_dumper ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeDumperGenerated.cpp

VERBATIM)

add_custom_target(Bytecodes DEPENDS "${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h")

string(TIMESTAMP BUILD_TIME "%s")

list(APPEND JavaScriptCore_HEADERS

${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeStructs.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h

)

if (WTF_CPU_X86_64)

set(OFFLINE_ASM_BACKEND "X86_64")

elseif (WTF_CPU_ARM64)

if (CMAKE_OSX_ARCHITECTURES STREQUAL "arm64e")

set(OFFLINE_ASM_BACKEND "ARM64E")

else ()

set(OFFLINE_ASM_BACKEND "ARM64")

endif ()

elseif (ARM_THUMB2_DETECTED)

set(OFFLINE_ASM_BACKEND "ARMv7")

elseif (WTF_CPU_RISCV64)

set(OFFLINE_ASM_BACKEND "RISCV64")

endif ()

if (NOT ENABLE_JIT)

if (ENABLE_C_LOOP)

set(OFFLINE_ASM_BACKEND "C_LOOP")

endif ()

endif ()

add_custom_command(

OUTPUT ${JavaScriptCore_DERIVED_SOURCES_DIR}/AirOpcode.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/AirOpcodeGenerated.h

MAIN_DEPENDENCY ${JAVASCRIPTCORE_DIR}/b3/air/AirOpcode.opcodes

DEPENDS ${JAVASCRIPTCORE_DIR}/b3/air/opcode_generator.rb

COMMAND ${Ruby_EXECUTABLE} ${JAVASCRIPTCORE_DIR}/b3/air/opcode_generator.rb ${JAVASCRIPTCORE_DIR}/b3/air/AirOpcode.opcodes VERBATIM

WORKING_DIRECTORY ${JavaScriptCore_DERIVED_SOURCES_DIR}

)

list(APPEND JavaScriptCore_HEADERS

${JavaScriptCore_DERIVED_SOURCES_DIR}/AirOpcode.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/AirOpcodeGenerated.h

)

add_custom_command(

OUTPUT ${JavaScriptCore_DERIVED_SOURCES_DIR}/LLIntDesiredSettings.h

MAIN_DEPENDENCY ${JAVASCRIPTCORE_DIR}/offlineasm/generate_settings_extractor.rb

DEPENDS ${LLINT_ASM} ${OFFLINE_ASM} ${JavaScriptCore_DERIVED_SOURCES_DIR}/InitBytecodes.asm

COMMAND ${Ruby_EXECUTABLE} ${JAVASCRIPTCORE_DIR}/offlineasm/generate_settings_extractor.rb -I${JavaScriptCore_DERIVED_SOURCES_DIR}/ ${OFFLINE_ASM_INCLUDE_DIRS} ${JAVASCRIPTCORE_DIR}/llint/LowLevelInterpreter.asm ${JavaScriptCore_DERIVED_SOURCES_DIR}/LLIntDesiredSettings.h ${OFFLINE_ASM_BACKEND} ${OFFLINE_ASM_ARGS}

VERBATIM)

add_custom_command(

OUTPUT ${JavaScriptCore_DERIVED_SOURCES_DIR}/LLIntDesiredOffsets.h

MAIN_DEPENDENCY ${JAVASCRIPTCORE_DIR}/offlineasm/generate_offset_extractor.rb

DEPENDS LLIntSettingsExtractor ${LLINT_ASM} ${OFFLINE_ASM} ${JavaScriptCore_DERIVED_SOURCES_DIR}/InitBytecodes.asm ${JavaScriptCore_DERIVED_SOURCES_DIR}/AirOpcode.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/WasmOps.h

COMMAND ${Ruby_EXECUTABLE} ${JAVASCRIPTCORE_DIR}/offlineasm/generate_offset_extractor.rb -I${JavaScriptCore_DERIVED_SOURCES_DIR}/ ${OFFLINE_ASM_INCLUDE_DIRS} ${JAVASCRIPTCORE_DIR}/llint/LowLevelInterpreter.asm $<TARGET_FILE:LLIntSettingsExtractor> ${JavaScriptCore_DERIVED_SOURCES_DIR}/LLIntDesiredOffsets.h ${OFFLINE_ASM_BACKEND} ${BUILD_VARIANTS} ${OFFLINE_ASM_ARGS}

VERBATIM)

# JSCBuiltins

set(BUILTINS_GENERATOR_SCRIPTS

${JavaScriptCore_SCRIPTS_DIR}/wkbuiltins.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generator.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_model.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_templates.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_combined_header.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_combined_implementation.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_separate_header.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_separate_implementation.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_wrapper_header.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_wrapper_implementation.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_internals_wrapper_header.py

${JavaScriptCore_SCRIPTS_DIR}/builtins_generate_internals_wrapper_implementation.py

${JavaScriptCore_SCRIPTS_DIR}/generate-js-builtins.py

${JavaScriptCore_SCRIPTS_DIR}/lazywriter.py

)

set(JavaScriptCore_BUILTINS_SOURCES

${JAVASCRIPTCORE_DIR}/builtins/AsyncFromSyncIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/ArrayConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/ArrayIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/ArrayPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/AsyncDisposableStackPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/AsyncGeneratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/AsyncIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/DisposableStackPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/FunctionPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/GeneratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/GlobalOperations.js

${JAVASCRIPTCORE_DIR}/builtins/IteratorHelpers.js

${JAVASCRIPTCORE_DIR}/builtins/JSIteratorConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/JSIteratorHelperPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/JSIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/MapConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/MapIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/MapPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/ObjectConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/PromiseConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/PromiseOperations.js

${JAVASCRIPTCORE_DIR}/builtins/ProxyHelpers.js

${JAVASCRIPTCORE_DIR}/builtins/ReflectObject.js

${JAVASCRIPTCORE_DIR}/builtins/RegExpPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/RegExpStringIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/SetIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/SetPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/ShadowRealmPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/StringConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/StringIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/TypedArrayConstructor.js

${JAVASCRIPTCORE_DIR}/builtins/TypedArrayPrototype.js

${JAVASCRIPTCORE_DIR}/builtins/WrapForValidIteratorPrototype.js

${JAVASCRIPTCORE_DIR}/inspector/InjectedScriptSource.js

)

add_custom_command(

OUTPUT ${JavaScriptCore_DERIVED_SOURCES_DIR}/JSCBuiltins.cpp ${JavaScriptCore_DERIVED_SOURCES_DIR}/JSCBuiltins.h

MAIN_DEPENDENCY ${JavaScriptCore_SCRIPTS_DIR}/generate-js-builtins.py

DEPENDS ${JavaScriptCore_BUILTINS_SOURCES} ${BUILTINS_GENERATOR_SCRIPTS}

COMMAND ${PYTHON_EXECUTABLE} ${JavaScriptCore_SCRIPTS_DIR}/generate-js-builtins.py --framework JavaScriptCore --output-directory ${JavaScriptCore_DERIVED_SOURCES_DIR} --combined ${JavaScriptCore_BUILTINS_SOURCES}

VERBATIM)

add_custom_target(JSCBuiltins DEPENDS "${JavaScriptCore_DERIVED_SOURCES_DIR}/JSCBuiltins.h")

# We add the header files directly to the ADD_EXECUTABLE call instead of setting the

# OBJECT_DEPENDS property in LLIntOffsetsExtractor.cpp because generate_offset_extractor.rb and

# generate-bytecode-files may not regenerate the .h files in case the hash it calculates does not change.

# In this case, if some of the dependencies specified in the ADD_CUSTOM_COMMANDs above have

# changed the command will always be called because the mtime of the .h files will

# always be older than that of their dependencies.

# Additionally, setting the OBJECT_DEPENDS property will make the .h files a Makefile

# dependency of both LLIntOffsetsExtractor and LLIntOffsetsExtractor.cpp, so the command will

# actually be run multiple times!

WEBKIT_EXECUTABLE_DECLARE(LLIntSettingsExtractor)

set(LLIntSettingsExtractor_SOURCES

${JAVASCRIPTCORE_DIR}/llint/LLIntSettingsExtractor.cpp

${JavaScriptCore_DERIVED_SOURCES_DIR}/LLIntDesiredSettings.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeStructs.h

)

set(LLIntSettingsExtractor_PRIVATE_INCLUDE_DIRECTORIES

$<TARGET_PROPERTY:JavaScriptCore,INCLUDE_DIRECTORIES>

"${JavaScriptCore_PRIVATE_FRAMEWORK_HEADERS_DIR}/JavaScriptCore"

)

set(LLIntSettingsExtractor_FRAMEWORKS)

set(LLIntSettingsExtractor_DEPENDENCIES

JavaScriptCore_CopyHeaders

JavaScriptCore_CopyPrivateHeaders

WTF_CopyHeaders

bmalloc_CopyHeaders

)

WEBKIT_EXECUTABLE(LLIntSettingsExtractor)

# LLIntSettingsExtractor target needs to have a direct or indirect

# dependency to Bytecodes target for CMake Visual Studio generator to

# eliminate duplicated custom commands. Otherwise, Bytecodes.h will be

# generated in both projects.

add_dependencies(LLIntSettingsExtractor Bytecodes)

WEBKIT_EXECUTABLE_DECLARE(LLIntOffsetsExtractor)

set(LLIntOffsetsExtractor_SOURCES

${JAVASCRIPTCORE_DIR}/llint/LLIntOffsetsExtractor.cpp

${JavaScriptCore_DERIVED_SOURCES_DIR}/LLIntDesiredOffsets.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h ${JavaScriptCore_DERIVED_SOURCES_DIR}/BytecodeStructs.h

)

set(LLIntOffsetsExtractor_PRIVATE_INCLUDE_DIRECTORIES

$<TARGET_PROPERTY:JavaScriptCore,INCLUDE_DIRECTORIES>

"${JavaScriptCore_PRIVATE_FRAMEWORK_HEADERS_DIR}/JavaScriptCore"

)

set(LLIntOffsetsExtractor_FRAMEWORKS)

set(LLIntOffsetsExtractor_DEPENDENCIES

JSCBuiltins

JavaScriptCore_CopyHeaders

JavaScriptCore_CopyPrivateHeaders

WTF_CopyHeaders

bmalloc_CopyHeaders

)

WEBKIT_EXECUTABLE(LLIntOffsetsExtractor)

# The build system will execute asm.rb every time LLIntOffsetsExtractor's mtime is newer than

# LLIntAssembly.h's mtime. The problem we have here is: asm.rb has some built-in optimization

# that generates a checksum of the LLIntOffsetsExtractor binary, if the checksum of the new

# LLIntOffsetsExtractor matches, no output is generated. To make this target consistent and avoid

# running this command for every build, we artificially update LLIntAssembly.h's mtime (using touch)

# after every asm.rb run.

set(LLIntOutput LLIntAssembly.h)

add_custom_command(

OUTPUT ${JavaScriptCore_DERIVED_SOURCES_DIR}/${LLIntOutput}

MAIN_DEPENDENCY ${JAVASCRIPTCORE_DIR}/offlineasm/asm.rb

DEPENDS LLIntOffsetsExtractor ${LLINT_ASM} ${OFFLINE_ASM} ${JavaScriptCore_DERIVED_SOURCES_DIR}/InitBytecodes.asm

COMMAND ${CMAKE_COMMAND} -E env CMAKE_CXX_COMPILER_ID=${CMAKE_CXX_COMPILER_ID} GCC_OFFLINEASM_SOURCE_MAP=${GCC_OFFLINEASM_SOURCE_MAP} ${Ruby_EXECUTABLE} ${JAVASCRIPTCORE_DIR}/offlineasm/asm.rb -I${JavaScriptCore_DERIVED_SOURCES_DIR}/ ${OFFLINE_ASM_INCLUDE_DIRS} ${JAVASCRIPTCORE_DIR}/llint/LowLevelInterpreter.asm $<TARGET_FILE:LLIntOffsetsExtractor> ${JavaScriptCore_DERIVED_SOURCES_DIR}/${LLIntOutput} ${BUILD_VARIANTS} ${OFFLINE_ASM_ARGS} ${OFFLINE_ASM_FORMAT_ARGS}

COMMAND ${CMAKE_COMMAND} -E touch_nocreate ${JavaScriptCore_DERIVED_SOURCES_DIR}/${LLIntOutput}

WORKING_DIRECTORY ${JavaScriptCore_DERIVED_SOURCES_DIR}

VERBATIM)

# The explanation for not making LLIntAssembly.h part of the OBJECT_DEPENDS property of some of

# the .cpp files below is similar to the one in the previous comment. However, since these .cpp

# files are used to build JavaScriptCore itself, we can just add LLIntAssembly.h to JSC_HEADERS

# since it is used in the add_library() call at the end of this file.

# As there's poor toolchain support for using `.file` directives in

# inline asm (i.e. there's no way to avoid clashes with the `.file`

# directives generated by the C code in the compilation unit), we

# introduce a postprocessing pass for the asm that gets assembled into

# an object file. We only need to do this for LowLevelInterpreter.cpp

# and cmake doesn't allow us to introduce a compiler wrapper for a

# single source file, so we need to create a separate target for it.

add_library(LowLevelInterpreterLib OBJECT llint/LowLevelInterpreter.cpp

${JavaScriptCore_DERIVED_SOURCES_DIR}/${LLIntOutput})

# WebAssembly generator

macro(GENERATE_PYTHON _generator _additional_deps _input _output)

add_custom_command(

OUTPUT ${_output}

MAIN_DEPENDENCY ${_generator}

DEPENDS ${_input} ${_additional_deps}

COMMAND ${PYTHON_EXECUTABLE} ${_generator} ${_input} ${_output}

VERBATIM)

list(APPEND JavaScriptCore_HEADERS ${_output})

WEBKIT_ADD_SOURCE_DEPENDENCIES(${_input} ${_output})

endmacro()

GENERATE_PYTHON(${CMAKE_CURRENT_SOURCE_DIR}/wasm/generateWasmOpsHeader.py ${CMAKE_CURRENT_SOURCE_DIR}/wasm/generateWasm.py ${CMAKE_CURRENT_SOURCE_DIR}/wasm/wasm.json ${JavaScriptCore_DERIVED_SOURCES_DIR}/WasmOps.h)

GENERATE_PYTHON(${CMAKE_CURRENT_SOURCE_DIR}/wasm/generateWasmOMGIRGeneratorInlinesHeader.py ${CMAKE_CURRENT_SOURCE_DIR}/wasm/generateWasm.py ${CMAKE_CURRENT_SOURCE_DIR}/wasm/wasm.json ${JavaScriptCore_DERIVED_SOURCES_DIR}/WasmOMGIRGeneratorInlines.h)

# LUT generator

set(HASH_LUT_GENERATOR ${CMAKE_CURRENT_SOURCE_DIR}/create_hash_table)

macro(GENERATE_HASH_LUT _input _output)

add_custom_command(

OUTPUT ${_output}

MAIN_DEPENDENCY ${HASH_LUT_GENERATOR}

DEPENDS ${_input}

COMMAND ${PERL_EXECUTABLE} ${HASH_LUT_GENERATOR} ${_input} > ${_output}

VERBATIM)

list(APPEND JavaScriptCore_HEADERS ${_output})

WEBKIT_ADD_SOURCE_DEPENDENCIES(${_input} ${_output})

endmacro()

# GENERATOR 1-A: LUT creator

foreach (_file ${JavaScriptCore_OBJECT_LUT_SOURCES})

get_filename_component(_name ${_file} NAME_WE)

GENERATE_HASH_LUT(${CMAKE_CURRENT_SOURCE_DIR}/${_file} ${JavaScriptCore_DERIVED_SOURCES_DIR}/${_name}.lut.h)

endforeach ()

set(JavaScriptCore_PUBLIC_FRAMEWORK_HEADERS

API/JSBase.h

API/JSContextRef.h

API/JSObjectRef.h

API/JSStringRef.h

API/JSTypedArray.h

API/JSValueRef.h

API/JavaScript.h

API/WebKitAvailability.h

)

set(JavaScriptCore_PRIVATE_FRAMEWORK_HEADERS

${JavaScriptCore_DERIVED_SOURCES_DIR}/Bytecodes.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/JSCBuiltins.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/WasmOps.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/inspector/InspectorAlternateBackendDispatchers.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/inspector/InspectorBackendDispatchers.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/inspector/InspectorFrontendDispatchers.h

${JavaScriptCore_DERIVED_SOURCES_DIR}/inspector/InspectorProtocolObjects.h

config.h

API/APICallbackFunction.h

API/APICast.h

API/APIIntegrityPrivate.h

API/JSAPIValueWrapper.h

API/JSBase.h

API/JSBasePrivate.h

API/JavaScript.h

API/JavaScriptCore.h

API/JSCTestRunnerUtils.h

API/JSCallbackConstructor.h

API/JSCallbackObject.h

API/JSClassRef.h

API/JSContext.h

API/JSContextInternal.h

API/JSContextPrivate.h

API/JSContextRef.h

API/JSContextRefInspectorSupport.h

API/JSContextRefPrivate.h

API/JSExport.h

API/JSHeapFinalizerPrivate.h

API/JSLockRefPrivate.h

API/JSManagedValue.h

API/JSMarkingConstraintPrivate.h

API/JSObjectRef.h

API/JSObjectRefPrivate.h

API/JSRemoteInspector.h

API/JSRetainPtr.h

API/JSScript.h

API/JSScriptRefPrivate.h

API/JSStringRef.h

API/JSStringRefCF.h

API/JSStringRefPrivate.h

API/JSTypedArray.h

API/JSValue.h

API/JSValueInternal.h

API/JSValuePrivate.h

API/JSValueRef.h

API/JSVirtualMachine.h

API/JSVirtualMachineInternal.h

API/JSVirtualMachinePrivate.h

API/JSWeakObjectMapRefInternal.h

API/JSWeakObjectMapRefPrivate.h

API/JSWeakPrivate.h

API/JSWeakValue.h

API/OpaqueJSString.h

API/glib/JSAPIWrapperGlobalObject.h

API/glib/JSCAutocleanups.h

API/glib/JSCCallbackFunction.h

API/glib/JSCClassPrivate.h

API/glib/JSCContextInternal.h

API/glib/JSCContextPrivate.h

API/glib/JSCExceptionPrivate.h

API/glib/JSCGLibWrapperObject.h

API/glib/JSCOptions.h

API/glib/JSCValuePrivate.h

API/glib/JSCVirtualMachinePrivate.h

API/glib/JSCWrapperMap.h

assembler/ARM64Assembler.h

assembler/ARM64EAssembler.h

assembler/ARM64Registers.h

assembler/ARMv7Assembler.h

assembler/ARMv7Registers.h

assembler/AbortReason.h

assembler/AbstractMacroAssembler.h

assembler/AllowMacroScratchRegisterUsage.h

assembler/AssemblerBuffer.h

assembler/AssemblerCommon.h

assembler/AssemblyComments.h

assembler/CPU.h

assembler/CodeLocation.h

assembler/DisallowMacroScratchRegisterUsage.h

assembler/FastJITPermissions.h

assembler/JITOperationList.h

assembler/JITOperationValidation.h

assembler/LinkBuffer.h

assembler/MacroAssembler.h

assembler/MacroAssemblerARM64.h

assembler/MacroAssemblerARMv7.h

assembler/MacroAssemblerCodeRef.h

assembler/MacroAssemblerHelpers.h

assembler/MacroAssemblerX86_64.h

assembler/MaxFrameExtentForSlowPathCall.h

assembler/OSCheck.h

assembler/Printer.h

assembler/ProbeContext.h

assembler/ProbeStack.h

assembler/RegisterInfo.h

assembler/SecureARM64EHashPins.h

assembler/SecureARM64EHashPinsInlines.h

assembler/TargetAssemblerDefinitions.h

assembler/X86Assembler.h

assembler/X86_64Registers.h

b3/air/AirAllocateRegistersByGraphColoring.h

b3/air/AirDisassembler.h

b3/B3CanonicalizePrePostIncrements.h

b3/B3Common.h

b3/B3Compile.h

b3/B3Type.h

b3/B3ValueRep.h

b3/testb3.h

builtins/BuiltinExecutables.h

builtins/BuiltinNames.h

builtins/BuiltinUtils.h

bytecode/ArithProfile.h

bytecode/ArrayAllocationProfile.h

bytecode/ArrayProfile.h

bytecode/BytecodeBasicBlock.h

bytecode/BytecodeConventions.h

bytecode/BytecodeGeneratorification.h

bytecode/BytecodeIndex.h

bytecode/BytecodeIntrinsicRegistry.h

bytecode/CallEdge.h

bytecode/CallLinkInfo.h

bytecode/CallLinkInfoBase.h

bytecode/CallMode.h

bytecode/CallVariant.h

bytecode/ChainedWatchpoint.h

bytecode/CodeBlock.h

bytecode/CodeBlockHash.h

bytecode/CodeBlockInlines.h

bytecode/CodeBlockJettisoningWatchpoint.h

bytecode/CodeBlockWithJITType.h

bytecode/CodeOrigin.h

bytecode/CodeType.h

bytecode/ComplexGetStatus.h

bytecode/DataFormat.h

bytecode/DeferredCompilationCallback.h

bytecode/DeferredSourceDump.h

bytecode/DFGExitProfile.h

bytecode/DirectEvalCodeCache.h

bytecode/ExecutableInfo.h

bytecode/ExecutionCounter.h

bytecode/ExitingInlineKind.h

bytecode/ExitingJITType.h

bytecode/ExitKind.h

bytecode/ExpressionInfo.h

bytecode/ExpressionInfoInlines.h

bytecode/HandlerInfo.h

bytecode/ICStatusMap.h

bytecode/InlineAccess.h

bytecode/InlineCallFrame.h

bytecode/InlineCallFrameSet.h

bytecode/Instruction.h

bytecode/InstructionStream.h

bytecode/InternalFunctionAllocationProfile.h

bytecode/IterationModeMetadata.h

bytecode/JumpTable.h

bytecode/LazyOperandValueProfile.h

bytecode/LazyValueProfile.h

bytecode/LineColumn.h

bytecode/LinkTimeConstant.h

bytecode/MetadataTable.h

bytecode/MethodOfGettingAValueProfile.h

bytecode/ObjectAllocationProfile.h

bytecode/ObjectPropertyCondition.h

bytecode/ObjectPropertyConditionSet.h

bytecode/Opcode.h

bytecode/OpcodeSize.h

bytecode/Operands.h

bytecode/OperandsInlines.h

bytecode/ParseHash.h

bytecode/PolyProtoAccessChain.h

bytecode/PreciseJumpTargets.h

bytecode/PropertyCondition.h

bytecode/PutByIdFlags.h

bytecode/ReduceWhitespace.h

bytecode/SourceID.h

bytecode/SpeculatedType.h

bytecode/StructureSet.h

bytecode/SuperSampler.h

bytecode/ToThisStatus.h

bytecode/TrackedReferences.h

bytecode/TypeLocation.h

bytecode/UnlinkedCodeBlock.h

bytecode/UnlinkedEvalCodeBlock.h

bytecode/UnlinkedFunctionCodeBlock.h

bytecode/UnlinkedFunctionExecutable.h

bytecode/UnlinkedGlobalCodeBlock.h

bytecode/UnlinkedMetadataTable.h

bytecode/UnlinkedModuleProgramCodeBlock.h

bytecode/UnlinkedProgramCodeBlock.h

bytecode/ValueProfile.h

bytecode/ValueRecovery.h

bytecode/VariableWriteFireDetail.h

bytecode/VirtualRegister.h

bytecode/Watchpoint.h

bytecompiler/StaticPropertyAnalysis.h

debugger/Breakpoint.h

debugger/Debugger.h

debugger/DebuggerCallFrame.h

debugger/DebuggerParseData.h

debugger/DebuggerPrimitives.h

debugger/ScriptProfilingScope.h

dfg/DFGCPSRethreadingPhase.h

dfg/DFGCodeOriginPool.h

dfg/DFGCommon.h

dfg/DFGCSEPhase.h

dfg/DFGDoesGCCheck.h

dfg/DFGInPlaceAbstractState.h

dfg/DFGLiveCatchVariablePreservationPhase.h

dfg/DFGMinifiedID.h

dfg/DFGRegisteredStructure.h

dfg/DFGRegisteredStructureSet.h

domjit/DOMJITAbstractHeap.h

domjit/DOMJITCallDOMGetterSnippet.h

domjit/DOMJITEffect.h

domjit/DOMJITGetterSetter.h

domjit/DOMJITHeapRange.h

domjit/DOMJITSignature.h

ftl/FTLAbbreviatedTypes.h

ftl/FTLCommonValues.h

ftl/FTLExitArgument.h

ftl/FTLExitArgumentForOperand.h

ftl/FTLExitValue.h

ftl/FTLFormattedValue.h

ftl/FTLLocation.h

ftl/FTLOSREntry.h

ftl/FTLRecoveryOpcode.h

ftl/FTLSaveRestore.h

ftl/FTLSlowPathCallKey.h

ftl/FTLStackmapArgumentList.h

ftl/FTLThunks.h

ftl/FTLValueFromBlock.h

ftl/FTLValueRange.h

heap/AbstractSlotVisitor.h

heap/AbstractSlotVisitorInlines.h

heap/AlignedMemoryAllocator.h

heap/AllocationFailureMode.h

heap/Allocator.h

heap/AllocatorInlines.h

heap/AllocatorForMode.h

heap/BlockDirectory.h

heap/BlockDirectoryBits.h

heap/BlockDirectoryInlines.h

heap/CellAttributes.h

heap/CellContainer.h

heap/CellContainerInlines.h

heap/CellState.h

heap/CollectionScope.h

heap/CollectorPhase.h

heap/CompleteSubspace.h

heap/CompleteSubspaceInlines.h

heap/ConstraintConcurrency.h

heap/ConstraintParallelism.h

heap/ConstraintVolatility.h

heap/DeferGC.h

heap/DeferGCInlines.h

heap/DeleteAllCodeEffort.h

heap/DestructionMode.h

heap/EdenGCActivityCallback.h

heap/FastMallocAlignedMemoryAllocator.h

heap/FreeList.h

heap/FreeListInlines.h

heap/FullGCActivityCallback.h

heap/GCActivityCallback.h

heap/GCAssertions.h

heap/GCConductor.h

heap/GCDeferralContext.h

heap/GCIncomingRefCounted.h

heap/GCIncomingRefCountedInlines.h

heap/GCIncomingRefCountedSet.h

heap/GCLogging.h

heap/GCMemoryOperations.h

heap/GCOwnedDataScope.h

heap/GCRequest.h

heap/GCSegmentedArray.h

heap/Handle.h

heap/HandleBlock.h

heap/HandleForward.h

heap/HandleSet.h

heap/HandleTypes.h

heap/Heap.h

heap/HeapAnalyzer.h

heap/HeapCell.h

heap/HeapCellInlines.h

heap/HeapCellType.h

heap/HeapFinalizerCallback.h

heap/HeapInlines.h

heap/HeapIterationScope.h

heap/HeapObserver.h

heap/HeapSnapshotBuilder.h

heap/IncrementalSweeper.h

heap/IsoCellSet.h

heap/IsoHeapCellType.h

heap/IsoInlinedHeapCellType.h

heap/IsoSubspace.h

heap/IsoSubspaceInlines.h

heap/LocalAllocator.h

heap/LocalAllocatorInlines.h

heap/MachineStackMarker.h

heap/MarkStack.h

heap/MarkedBlock.h

heap/MarkedBlockInlines.h

heap/MarkedBlockSet.h

heap/MarkedSpace.h

heap/MarkedSpaceInlines.h

heap/MarkingConstraint.h

heap/MutatorState.h

heap/PackedCellPtr.h

heap/PreciseAllocation.h

heap/PreciseSubspace.h

heap/RegisterState.h

heap/RootMarkReason.h

heap/RunningScope.h

heap/SlotVisitor.h

heap/SlotVisitorInlines.h

heap/SlotVisitorMacros.h

heap/Strong.h

heap/StrongForward.h

heap/StrongInlines.h

heap/Subspace.h

heap/SubspaceInlines.h

heap/Synchronousness.h

heap/TinyBloomFilter.h

heap/VerifierSlotVisitor.h

heap/VisitRaceKey.h

heap/Weak.h

heap/WeakBlock.h

heap/WeakHandleOwner.h

heap/WeakImpl.h

heap/WeakInlines.h

heap/WeakInlinesLight.h

heap/WeakSet.h

heap/WeakSetInlines.h

inspector/AsyncStackTrace.h

inspector/ConsoleMessage.h

inspector/ContentSearchUtilities.h

inspector/IdentifiersFactory.h

inspector/InjectedScript.h

inspector/InjectedScriptBase.h

inspector/InjectedScriptHost.h

inspector/InjectedScriptManager.h

inspector/InjectedScriptModule.h

inspector/InspectorAgentBase.h

inspector/InspectorAgentRegistry.h

inspector/InspectorBackendDispatcher.h

inspector/InspectorEnvironment.h

inspector/InspectorFrontendChannel.h

inspector/InspectorFrontendRouter.h

inspector/InspectorProtocolTypes.h

inspector/InspectorTarget.h

inspector/PerGlobalObjectWrapperWorld.h

inspector/ScriptArguments.h

inspector/ScriptCallFrame.h

inspector/ScriptCallStack.h

inspector/ScriptCallStackFactory.h

inspector/ScriptFunctionCall.h

inspector/agents/InspectorAgent.h

inspector/agents/InspectorAuditAgent.h

inspector/agents/InspectorConsoleAgent.h

inspector/agents/InspectorDebuggerAgent.h

inspector/agents/InspectorHeapAgent.h

inspector/agents/InspectorRuntimeAgent.h

inspector/agents/InspectorScriptProfilerAgent.h

inspector/agents/InspectorTargetAgent.h

inspector/augmentable/AugmentableInspectorControllerClient.h

inspector/remote/RemoteAutomationTarget.h

inspector/remote/RemoteConnectionToTarget.h

inspector/remote/RemoteControllableTarget.h

inspector/remote/RemoteInspectionTarget.h

inspector/remote/RemoteInspector.h

interpreter/CachedCall.h

interpreter/CachedCallInlines.h

interpreter/CalleeBits.h

interpreter/CallFrame.h

interpreter/CallFrameInlines.h

interpreter/CheckpointOSRExitSideState.h

interpreter/CLoopStack.h

interpreter/CLoopStackInlines.h

interpreter/EntryFrame.h

interpreter/FrameTracers.h

interpreter/Interpreter.h

interpreter/MicrotaskCall.h

interpreter/MicrotaskCallInlines.h

interpreter/ProtoCallFrame.h

interpreter/ProtoCallFrameInlines.h

interpreter/Register.h

interpreter/RegisterInlines.h

interpreter/ShadowChicken.h

interpreter/ShadowChickenInlines.h

interpreter/StackVisitor.h

interpreter/VMEntryRecord.h

jit/AssemblyHelpers.h

jit/AssemblyHelpersSpoolers.h

jit/BaselineJITRegisters.h

jit/CallFrameShuffleData.h

jit/CCallHelpers.h

jit/ExecutableAllocator.h

jit/ExecutableMemoryHandle.h

jit/FPRInfo.h

jit/GCAwareJITStubRoutine.h

jit/GPRInfo.h

jit/JITAllocator.h

jit/JITCode.h

jit/JITCodeMap.h

jit/JITCompilation.h

jit/JITCompilationEffort.h

jit/JITCompilationMode.h

jit/JITMathICForwards.h

jit/JITOperations.h

jit/JITStubRoutine.h

jit/JITThunks.h

jit/OperationResult.h

jit/PCToCodeOriginMap.h

jit/PolymorphicCallStubRoutine.h

jit/Reg.h

jit/RegisterAtOffset.h

jit/RegisterAtOffsetList.h

jit/RegisterMap.h

jit/RegisterSet.h

jit/SIMDInfo.h

jit/SIMDShuffle.h

jit/SimpleRegisterAllocator.h

jit/ScratchRegisterAllocator.h

jit/Snippet.h

jit/SnippetParams.h

jit/SnippetReg.h

jit/SnippetSlowPathCalls.h

jit/SpillRegistersMode.h

jit/TagRegistersMode.h

jit/ThunkGenerator.h

jit/Width.h

llint/InPlaceInterpreter.h

llint/LLIntCLoop.h

llint/LLIntCommon.h

llint/LLIntEntrypoint.h

llint/LLIntExceptions.h

llint/LLIntOfflineAsmConfig.h