Extract implicit fuzzy indent blacklist patterns

guns · guns · commit 4e13b467db66 · 2013-01-08T15:58:07.000-06:00
Meikel started the fuzzy indent feature as a simple match against def.*, let.*, and with.*. Then he added exceptions for syms ending in -fn, and then a special case match for 'with-meta'. After this, the fuzzy indent patterns were made a public option, but the hardcoded exceptions remained. This commit finishes this refactoring and gives full control to the user. The new blacklist, and the former pattern whitelist are now lists by default to allow for any kind of pattern (e.g. '\V\cFOO'), instead of an implicitly anchored one that cannot be preceded by pattern modifiers. The old string options are supported for backwards compatibility. Addresses #7
diff --git a/indent/clojure.vim b/indent/clojure.vim
@@ -35,8 +35,12 @@ if exists("*searchpairpos")
         let g:clojure_fuzzy_indent = 1
     endif
 
-    if !exists("g:clojure_fuzzy_indent_patterns")
-        let g:clojure_fuzzy_indent_patterns = "with.*,def.*,let.*"
+    if !exists('g:clojure_fuzzy_indent_patterns')
+        let g:clojure_fuzzy_indent_patterns = ['^with', '^def', '^let']
+    endif
+
+    if !exists('g:clojure_fuzzy_indent_blacklist')
+        let g:clojure_fuzzy_indent_blacklist = ['^with-meta$', '-fn$']
     endif
 
     if !exists('g:clojure_special_indent_words')
@@ -64,6 +68,18 @@ if exists("*searchpairpos")
              \ s:SynIdName() !~? '\vstring|comment'
     endfunction
 
+    " Returns 1 if string matches a pattern in 'patterns', which may be a
+    " list of patterns, or a comma-delimited string of implicitly anchored
+    " patterns.
+    function! s:MatchesOne(patterns, string)
+        let list = type(a:patterns) == type([])
+                   \ ? a:patterns
+                   \ : map(split(a:patterns, ','), '"^" . v:val . "$"')
+        for pat in list
+            if a:string =~ pat | return 1 | endif
+        endfor
+    endfunction
+
     function! s:SavePosition()
         let [ _b, l, c, _o ] = getpos(".")
         let b = bufnr("%")
@@ -271,14 +287,9 @@ if exists("*searchpairpos")
         endif
 
         if g:clojure_fuzzy_indent
-            \ && ww != 'with-meta'
-            for pat in split(g:clojure_fuzzy_indent_patterns, ",")
-                if ww =~ '^' . pat . '$'
-                    \ && ww !~ '^' . pat . '\*$'
-                    \ && ww !~ '^' . pat . '-fn$'
-                    return paren[1] + &shiftwidth - 1
-                endif
-            endfor
+            \ && !s:MatchesOne(g:clojure_fuzzy_indent_blacklist, ww)
+            \ && s:MatchesOne(g:clojure_fuzzy_indent_patterns, ww)
+            return paren[1] + &shiftwidth - 1
         endif
 
         normal! W
