forked from taskflow/taskflow
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathfor_each.hpp
More file actions
315 lines (243 loc) · 7.67 KB
/
Copy pathfor_each.hpp
File metadata and controls
315 lines (243 loc) · 7.67 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
#pragma once
#include "../cudaflow.hpp"
/**
@file taskflow/cuda/algorithm/for_each.hpp
@brief cuda parallel-iteration algorithms include file
*/
namespace tf {
namespace detail {
/**
@private
*/
template <size_t nt, size_t vt, typename I, typename C>
__global__ void cuda_for_each_kernel(I first, unsigned count, C c) {
auto tid = threadIdx.x;
auto bid = blockIdx.x;
auto tile = cuda_get_tile(bid, nt*vt, count);
cuda_strided_iterate<nt, vt>(
[=](auto, auto j) {
c(*(first + tile.begin + j));
},
tid, tile.count()
);
}
/** @private */
template <size_t nt, size_t vt, typename I, typename C>
__global__ void cuda_for_each_index_kernel(I first, I inc, unsigned count, C c) {
auto tid = threadIdx.x;
auto bid = blockIdx.x;
auto tile = cuda_get_tile(bid, nt*vt, count);
cuda_strided_iterate<nt, vt>(
[=]__device__(auto, auto j) {
c(first + inc*(tile.begin+j));
},
tid, tile.count()
);
}
} // end of namespace detail -------------------------------------------------
// ----------------------------------------------------------------------------
// cuda standard algorithms: single_task/for_each/for_each_index
// ----------------------------------------------------------------------------
/**
@brief runs a callable asynchronously using one kernel thread
@tparam P execution policy type
@tparam C closure type
@param p execution policy
@param c closure to run by one kernel thread
The function launches a single kernel thread to run the given callable
through the stream in the execution policy object.
*/
template <typename P, typename C>
void cuda_single_task(P&& p, C c) {
cuda_kernel<<<1, 1, 0, p.stream()>>>(
[=]__device__(auto, auto) mutable { c(); }
);
}
/**
@brief performs asynchronous parallel iterations over a range of items
@tparam P execution policy type
@tparam I input iterator type
@tparam C unary operator type
@param p execution policy object
@param first iterator to the beginning of the range
@param last iterator to the end of the range
@param c unary operator to apply to each dereferenced iterator
This function is equivalent to a parallel execution of the following loop
on a GPU:
@code{.cpp}
for(auto itr = first; itr != last; itr++) {
c(*itr);
}
@endcode
*/
template <typename P, typename I, typename C>
void cuda_for_each(P&& p, I first, I last, C c) {
using E = std::decay_t<P>;
unsigned count = std::distance(first, last);
if(count == 0) {
return;
}
detail::cuda_for_each_kernel<E::nt, E::vt, I, C><<<E::num_blocks(count), E::nt, 0, p.stream()>>>(
first, count, c
);
}
/**
@brief performs asynchronous parallel iterations over
an index-based range of items
@tparam P execution policy type
@tparam I input index type
@tparam C unary operator type
@param p execution policy object
@param first index to the beginning of the range
@param last index to the end of the range
@param inc step size between successive iterations
@param c unary operator to apply to each index
This function is equivalent to a parallel execution of
the following loop on a GPU:
@code{.cpp}
// step is positive [first, last)
for(auto i=first; i<last; i+=step) {
c(i);
}
// step is negative [first, last)
for(auto i=first; i>last; i+=step) {
c(i);
}
@endcode
*/
template <typename P, typename I, typename C>
void cuda_for_each_index(P&& p, I first, I last, I inc, C c) {
using E = std::decay_t<P>;
unsigned count = distance(first, last, inc);
if(count == 0) {
return;
}
detail::cuda_for_each_index_kernel<E::nt, E::vt, I, C><<<E::num_blocks(count), E::nt, 0, p.stream()>>>(
first, inc, count, c
);
}
// ----------------------------------------------------------------------------
// single_task
// ----------------------------------------------------------------------------
/** @private */
template <typename C>
__global__ void cuda_single_task(C callable) {
callable();
}
// Function: single_task
template <typename C>
cudaTask cudaFlow::single_task(C c) {
return kernel(1, 1, 0, cuda_single_task<C>, c);
}
// Function: single_task
template <typename C>
void cudaFlow::single_task(cudaTask task, C c) {
return kernel(task, 1, 1, 0, cuda_single_task<C>, c);
}
// Function: single_task
template <typename C>
cudaTask cudaFlowCapturer::single_task(C callable) {
return on([=] (cudaStream_t stream) mutable {
cuda_single_task(cudaDefaultExecutionPolicy(stream), callable);
});
}
// Function: single_task
template <typename C>
void cudaFlowCapturer::single_task(cudaTask task, C callable) {
on(task, [=] (cudaStream_t stream) mutable {
cuda_single_task(cudaDefaultExecutionPolicy(stream), callable);
});
}
// ----------------------------------------------------------------------------
// cudaFlow: for_each, for_each_index
// ----------------------------------------------------------------------------
// Function: for_each
template <typename I, typename C>
cudaTask cudaFlow::for_each(I first, I last, C c) {
using E = cudaDefaultExecutionPolicy;
unsigned count = std::distance(first, last);
// TODO:
//if(count == 0) {
// return;
//}
return kernel(
E::num_blocks(count), E::nt, 0,
detail::cuda_for_each_kernel<E::nt, E::vt, I, C>, first, count, c
);
}
// Function: for_each
template <typename I, typename C>
void cudaFlow::for_each(cudaTask task, I first, I last, C c) {
using E = cudaDefaultExecutionPolicy;
unsigned count = std::distance(first, last);
// TODO:
//if(count == 0) {
// return;
//}
kernel(task,
E::num_blocks(count), E::nt, 0,
detail::cuda_for_each_kernel<E::nt, E::vt, I, C>, first, count, c
);
}
// Function: for_each_index
template <typename I, typename C>
cudaTask cudaFlow::for_each_index(I first, I last, I inc, C c) {
using E = cudaDefaultExecutionPolicy;
unsigned count = distance(first, last, inc);
// TODO:
//if(count == 0) {
// return;
//}
return kernel(
E::num_blocks(count), E::nt, 0,
detail::cuda_for_each_index_kernel<E::nt, E::vt, I, C>, first, inc, count, c
);
}
// Function: for_each_index
template <typename I, typename C>
void cudaFlow::for_each_index(cudaTask task, I first, I last, I inc, C c) {
using E = cudaDefaultExecutionPolicy;
unsigned count = distance(first, last, inc);
// TODO:
//if(count == 0) {
// return;
//}
return kernel(task,
E::num_blocks(count), E::nt, 0,
detail::cuda_for_each_index_kernel<E::nt, E::vt, I, C>, first, inc, count, c
);
}
// ----------------------------------------------------------------------------
// cudaFlowCapturer: for_each, for_each_index
// ----------------------------------------------------------------------------
// Function: for_each
template <typename I, typename C>
cudaTask cudaFlowCapturer::for_each(I first, I last, C c) {
return on([=](cudaStream_t stream) mutable {
cuda_for_each(cudaDefaultExecutionPolicy(stream), first, last, c);
});
}
// Function: for_each_index
template <typename I, typename C>
cudaTask cudaFlowCapturer::for_each_index(I beg, I end, I inc, C c) {
return on([=] (cudaStream_t stream) mutable {
cuda_for_each_index(cudaDefaultExecutionPolicy(stream), beg, end, inc, c);
});
}
// Function: for_each
template <typename I, typename C>
void cudaFlowCapturer::for_each(cudaTask task, I first, I last, C c) {
on(task, [=](cudaStream_t stream) mutable {
cuda_for_each(cudaDefaultExecutionPolicy(stream), first, last, c);
});
}
// Function: for_each_index
template <typename I, typename C>
void cudaFlowCapturer::for_each_index(
cudaTask task, I beg, I end, I inc, C c
) {
on(task, [=] (cudaStream_t stream) mutable {
cuda_for_each_index(cudaDefaultExecutionPolicy(stream), beg, end, inc, c);
});
}
} // end of namespace tf -----------------------------------------------------